1 files changed, 54 insertions, 0 deletions
diff --git a/media-sound/amsynth/amsynth-1.2.2.ebuild b/media-sound/amsynth/amsynth-1.2.2.ebuild
new file mode 100644
index 000000000000..0178ad0e4f69
--- /dev/null
+++ b/media-sound/amsynth/amsynth-1.2.2.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/amsynth/amsynth-1.2.2.ebuild,v 1.1 2009/08/28 18:18:30 ssuominen Exp $
+
+EAPI=2
+MY_P=${P/ams/amS}
+inherit autotools eutils
+
+DESCRIPTION="Virtual analogue synthesizer."
+HOMEPAGE="http://amsynthe.sourceforge.net/"
+SRC_URI="mirror://sourceforge/amsynthe/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="alsa debug jack oss sndfile"
+
+RDEPEND=">=dev-cpp/gtkmm-2.4
+	sndfile? ( >=media-libs/libsndfile-1 )
+	alsa? ( media-libs/alsa-lib
+		media-sound/alsa-utils )
+	jack? ( media-sound/jack-audio-connection-kit )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-asneeded.patch
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_with oss) \
+		$(use_with alsa) \
+		$(use_with jack) \
+		$(use_with sndfile) \
+		$(use_enable debug)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dodoc AUTHORS README
+}
+
+pkg_postinst() {
+	elog
+	elog "amSynth has been installed normally. If you would like to use"
+	elog "the virtual keyboard option, then do:"
+	elog "# emerge vkeybd"
+	elog "and make sure you emerged amSynth with alsa support (USE=alsa)"
+	elog
+}