1 files changed, 54 insertions, 0 deletions
diff --git a/net-libs/libktorrent/libktorrent-1.0.2.ebuild b/net-libs/libktorrent/libktorrent-1.0.2.ebuild
new file mode 100644
index 000000000000..84f36fd61e91
--- /dev/null
+++ b/net-libs/libktorrent/libktorrent-1.0.2.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libktorrent/libktorrent-1.0.2.ebuild,v 1.1 2010/07/09 11:39:56 scarabeus Exp $
+
+EAPI="2"
+
+if [[ ${PV} == *9999* ]] ; then
+	KMNAME="extragear/network"
+else
+	# upstream likes to skip that _ in beta releases
+	KTORRENT_VERSION="4.0.2"
+	MY_PV="${PV/_/}"
+	MY_P="${PN}-${MY_PV}"
+
+	KDE_LINGUAS="ar ast be bg ca ca@valencia cs da de el en_GB eo es et eu
+		fi fr ga gl hi hne hr hu is it ja km ku lt lv ms nb nds nl nn oc pl
+		pt pt_BR ro ru se si sk sl sr sr@ijekavian sr@ijekavianlatin
+		sr@latin sv tr uk zh_CN zh_TW"
+	SRC_URI="http://ktorrent.org/downloads/${KTORRENT_VERSION}/${MY_P}.tar.bz2"
+	S="${WORKDIR}"/"${MY_P}"
+fi
+
+inherit kde4-base
+
+DESCRIPTION="A BitTorrent library based on KDE Platform"
+HOMEPAGE="http://ktorrent.org/"
+
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+SLOT="4"
+IUSE="debug doc"
+
+COMMONDEPEND="
+	app-crypt/qca:2
+	dev-libs/gmp
+"
+DEPEND="${COMMONDEPEND}
+	dev-libs/boost
+	sys-devel/gettext
+	doc? ( app-doc/doxygen[-nodot] )
+"
+RDEPEND="${COMMONDEPEND}"
+
+src_compile() {
+	cmake-utils_src_compile
+
+	use doc && cmake-utils_src_compile docs
+}
+
+src_install() {
+	use doc && HTML_DOCS=("${CMAKE_BUILD_DIR}/apidocs/html/")
+
+	cmake-utils_src_install
+}