dev-perl/Image-Scale/Image-Scale-0.80.0-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-perl/Image-Scale/Image-Scale-0.80.0-r1.ebuild,v 1.1 2014/08/26 17:01:28 axs Exp $

EAPI=5

MODULE_AUTHOR=AGRUNDMA
MODULE_VERSION=0.08
inherit perl-module

DESCRIPTION="Fast, high-quality fixed-point image resizing"

LICENSE="|| ( GPL-2 GPL-3 )" # GPL2+
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+gif jpeg +png test"

REQUIRED_USE="|| ( jpeg png )"

RDEPEND="
	png? (
		media-libs/libpng:0
	)
	jpeg? (
		virtual/jpeg
	)
	gif? (
		media-libs/giflib
	)
"
DEPEND="${RDEPEND}
	test? (
		dev-perl/Test-NoWarnings
	)
	virtual/perl-ExtUtils-MakeMaker
"

SRC_TEST=do
PATCHES=(
	"${FILESDIR}"/libpng-1.5-memcpy.patch
	"${FILESDIR}"/0.80.0-disable_autodetect.patch
)

src_configure() {
	local myconf
	for useflag in png jpeg gif; do
		myconf+=( $(usex $useflag "" --disable-${useflag}) )
	done
	perl-module_src_configure
}