dev-tex/xymtex/xymtex-5.00a.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-tex/xymtex/xymtex-5.00a.ebuild,v 1.3 2012/06/02 12:10:21 johu Exp $

EAPI=4

inherit latex-package versionator

DESCRIPTION="LaTeX package for rendering high-quality chemical structure diagrams"
HOMEPAGE="http://xymtex.com/"
MY_PV="$(delete_all_version_separators)"
SRC_URI="${HOMEPAGE}/fujitas3/${PN}/xym${MY_PV}/xym-up/${PN}${MY_PV}.zip"
LICENSE="LPPL-1.3"

SLOT="0"
KEYWORDS="amd64 x86"
IUSE=""

DEPEND="app-arch/unzip"
RDEPEND=""

S="${WORKDIR}/${PN}"

TEXMF=/usr/share/texmf-site

src_compile() {
	local subdir
	for subdir in base chemist xymtxpdf xymtxps; do
		cd "${S}/${subdir}" || die
		latex-package_src_compile
	done
}

src_install() {
	local subdir
	for subdir in base chemist xymtxpdf xymtxps; do
		cd "${S}/${subdir}" || die
		latex-package_src_install
	done

	# cd "${S}/doc/doc${MY_PV}/" || die
	cd "${S}/doc/doc500/" || die
	latex-package_src_doinstall pdf
}