dev-vcs/hgsubversion/hgsubversion-1.2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-vcs/hgsubversion/hgsubversion-1.2.ebuild,v 1.3 2011/01/26 18:30:39 hwoarang Exp $

EAPI="3"
PYTHON_DEPEND="2"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="3.* *-jython"

inherit distutils

DESCRIPTION="hgsubversion is a Mercurial extension for working with Subversion repositories."
HOMEPAGE="http://bitbucket.org/durin42/hgsubversion http://pypi.python.org/pypi/hgsubversion"
SRC_URI="http://bitbucket.org/durin42/${PN}/get/${PV}.tar.gz -> ${PN}-${PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 x86 ~ppc-macos ~x86-solaris"
IUSE="test"

RDEPEND=">=dev-vcs/mercurial-1.4
		>=dev-vcs/subversion-1.5[python]"
DEPEND="test? ( dev-python/nose )"

S="${WORKDIR}/${PN}"

DOCS="README"

src_prepare() {
	distutils_src_prepare

	# Disable failing tests.
	sed \
		-e "s/test_many_special_cases_diff/_&/" \
		-e "212s/test_oldest_not_trunk_and_tag_vendor_branch/_&/" \
		-i tests/test_fetch_command.py
	sed -e "s/test_exec_stupid/_&/" -i tests/test_fetch_exec.py
	sed -e "s/test_case_stupid/_&/" -i tests/test_fetch_renames.py
	sed -e "s/test_symlinks_stupid/_&/" -i tests/test_fetch_symlinks.py
}

src_test() {
	cd tests

	testing() {
		PYTHONPATH="../build-${PYTHON_ABI}/lib" "$(PYTHON)" run.py
	}
	python_execute_function testing
}