gnome-extra/gucharmap/gucharmap-3.4.1.1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gucharmap/gucharmap-3.4.1.1.ebuild,v 1.3 2012/10/04 14:54:31 ago Exp $

EAPI="4"
GCONF_DEBUG="yes"
GNOME2_LA_PUNT="yes"

inherit gnome2

DESCRIPTION="Unicode character map viewer and library"
HOMEPAGE="http://live.gnome.org/Gucharmap"

LICENSE="GPL-3"
SLOT="2.90"
KEYWORDS="~alpha amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc x86 ~x86-fbsd"
IUSE="cjk doc +introspection test"

COMMON_DEPEND=">=dev-libs/glib-2.25.3
	>=x11-libs/pango-1.2.1[introspection?]
	>=x11-libs/gtk+-3.0.0:3[introspection?]

	introspection? ( >=dev-libs/gobject-introspection-0.9.0 )"
RDEPEND="${COMMON_DEPEND}
	!<gnome-extra/gucharmap-3:0"
DEPEND="${RDEPEND}
	app-text/scrollkeeper
	virtual/pkgconfig
	>=dev-util/intltool-0.40
	>=app-text/gnome-doc-utils-0.9.0

	sys-devel/gettext

	doc? ( >=dev-util/gtk-doc-1.0 )
	test? ( ~app-text/docbook-xml-dtd-4.1.2 )"

pkg_setup() {
	G2CONF="${G2CONF}
		--disable-static
		--disable-scrollkeeper
		$(use_enable introspection)
		$(use_enable cjk unihan)"
	DOCS="AUTHORS ChangeLog NEWS README TODO"
}

src_prepare() {
	# prevent file collisions with slot 0
	sed -e "s:GETTEXT_PACKAGE=gucharmap$:GETTEXT_PACKAGE=gucharmap-${SLOT}:" \
		-i configure.ac configure || die "sed configure.ac configure failed"

	gnome2_src_prepare

	# avoid autoreconf
	sed -e 's/-Wall //g' -i configure || die "sed failed"
}