blob: 91cfde69beccc817fab00594e0ffa7566cbd17f5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mail-client/sylpheed/sylpheed-2.5.0.ebuild,v 1.2 2008/06/23 09:24:52 hattya Exp $
inherit autotools eutils
IUSE="crypt ipv6 ldap nls pda spell ssl xface"
DESCRIPTION="A lightweight email client and newsreader"
HOMEPAGE="http://sylpheed.sraoss.jp/"
SRC_URI="http://sylpheed.sraoss.jp/${PN}/v${PV%.*}/${P}.tar.bz2"
LICENSE="GPL-2 LGPL-2.1"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
SLOT="0"
COMMON_DEPEND=">=x11-libs/gtk+-2.4
nls? ( >=sys-devel/gettext-0.12.1 )
crypt? ( >=app-crypt/gpgme-0.4.5 )
ldap? ( >=net-nds/openldap-2.0.11 )
pda? ( app-pda/jpilot )
spell? ( app-text/gtkspell )
ssl? ( dev-libs/openssl )"
DEPEND="${COMMON_DEPEND}
dev-util/pkgconfig
xface? ( >=media-libs/compface-1.4 )"
RDEPEND="${COMMON_DEPEND}
app-misc/mime-types
x11-misc/shared-mime-info"
AT_M4DIR="ac"
src_unpack() {
unpack ${A}
cd "${S}"
epatch "${FILESDIR}"/${PN}-2.*.diff
use crypt || cp ac/missing/gpgme.m4 ac
# remove "-I m4" from aclocal arguments
sed -i "/^ACLOCAL_AMFLAGS/d" Makefile.am
eautomake
}
src_compile() {
local htmldir=/usr/share/doc/${PF}/html
econf \
$(use_enable crypt gpgme) \
$(use_enable ipv6) \
$(use_enable ldap) \
$(use_enable nls) \
$(use_enable pda jpilot) \
$(use_enable spell gtkspell) \
$(use_enable ssl) \
$(use_enable xface compface) \
--with-manualdir=${htmldir}/manual \
--with-faqdir=${htmldir}/faq \
|| die
emake || die
}
src_install() {
emake DESTDIR="${D}" install || die
dodoc AUTHORS ChangeLog* NEWS* README* TODO*
doicon *.png
domenu *.desktop
}
|
GitWeb