media-sound/zinf/zinf-2.2.5-r3.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/zinf/zinf-2.2.5-r3.ebuild,v 1.2 2006/01/27 23:42:48 ticho Exp $

inherit kde-functions eutils flag-o-matic libtool

DESCRIPTION="An extremely full-featured mp3/vorbis/cd player with ALSA support, previously called FreeAmp"
HOMEPAGE="http://www.zinf.org/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86 -sparc"
IUSE="alsa arts corba debug esd gtk ipv6 mp3 nls vorbis xosd X"

RDEPEND=">=dev-libs/glib-2
	sys-libs/gdbm
	sys-libs/zlib
	>=sys-libs/ncurses-5.2
	>=media-libs/musicbrainz-1.0.1
	alsa? ( >=media-libs/alsa-lib-0.9.8 )
	arts? ( kde-base/arts )
	corba? ( =gnome-base/orbit-0* )
	esd? ( >=media-sound/esound-0.2.12 )
	gtk? ( >=x11-libs/gtk+-2 )
	mp3? ( >=media-libs/id3lib-3.8.0 )
	vorbis? ( media-libs/libvorbis )
	xosd? ( x11-libs/xosd )"

# When updating next, check boost to see if the newer versions fix compilation
DEPEND="${RDEPEND}
	dev-lang/perl
	>=sys-devel/automake-1.7
	nls? ( sys-devel/gettext )
	x86? ( dev-lang/nasm )"
#	experimental? (
#		>=dev-cpp/gtkmm-2
#		app-office/mdbtools
#		dev-db/metakit
#		dev-libs/boost
#	)

src_unpack() {
	unpack ${A}; cd "${S}"

	epatch "${FILESDIR}"/${P}-cdplay.patch
	epatch "${FILESDIR}"/${P}-configure.patch
	epatch "${FILESDIR}"/${P}-rtp.patch

	export WANT_AUTOMAKE=1.7
	export WANT_AUTOCONF=2.5

	touch aclocal.m4

	ebegin "Running automake (${WANT_AUTOMAKE})"
	automake || die
	eend $?

	ebegin "Running autoconf (${WANT_AUTOCONF})"
	autoconf || die
	eend $?

	# fix #94149
	elibtoolize
}

src_compile() {
	local myconf

	myconf="${myconf} --enable-cmdline"

	# --disable-xosd is bork, #94143.
	if use xosd ; then
		myconf="${myconf} --enable-xosd"
	fi

	# --disable-corba is also bork.
	if use corba ; then
		myconf="${myconf} --enable-corba"
	fi

	if use amd64; then
		replace-flags -O? -O
		append-flags -frerun-cse-after-loop
	fi

	econf \
		$(use_enable alsa) \
		$(use_enable arts) \
		$(use_enable debug) \
		$(use_enable esd) \
		$(use_enable ipv6) \
		$(use_enable nls) \
		$(use_enable x86 x86opts) \
		${myconf} || die
	emake || die
}

src_install() {
	make DESTDIR="${D}" install || die
}