blob: cd186815dc08d2328373035c58f3137abff3532b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
|
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-geosciences/googleearth/googleearth-5.1.3533.1731-r1.ebuild,v 1.1 2010/03/16 09:14:19 caster Exp $
EAPI=2
inherit eutils fdo-mime versionator toolchain-funcs
DESCRIPTION="A 3D interface to the planet"
HOMEPAGE="http://earth.google.com/"
# no upstream versioning, version determined from help/about
# incorrect digest means upstream bumped and thus needs version bump
SRC_URI="http://dl.google.com/earth/client/current/GoogleEarthLinux.bin
-> GoogleEarthLinux-${PV}.bin"
LICENSE="googleearth MIT SGI-B-1.1 openssl as-is ZLIB"
SLOT="0"
KEYWORDS="~amd64 ~x86"
RESTRICT="mirror strip"
IUSE="qt-bundled"
GCC_NEEDED="4.2"
RDEPEND=">=sys-devel/gcc-${GCC_NEEDED}[-nocxx]
x86? (
media-libs/fontconfig
media-libs/freetype
virtual/opengl
x11-libs/libICE
x11-libs/libSM
x11-libs/libX11
x11-libs/libXi
x11-libs/libXext
x11-libs/libXrender
x11-libs/libXau
x11-libs/libXdmcp
sys-libs/zlib
dev-libs/glib:2
!qt-bundled? (
>=x11-libs/qt-core-4.5.3
>=x11-libs/qt-gui-4.5.3
>=x11-libs/qt-webkit-4.5.3
)
)
amd64? (
>=app-emulation/emul-linux-x86-xlibs-20081109
>=app-emulation/emul-linux-x86-baselibs-20081109
!qt-bundled? (
>=app-emulation/emul-linux-x86-qtlibs-20091231-r1
)
)
|| (
media-fonts/dejavu
media-fonts/ttf-bitstream-vera
)"
S="${WORKDIR}"
QA_TEXTRELS="opt/googleearth/libgps.so
opt/googleearth/libgooglesearch.so
opt/googleearth/libevll.so
opt/googleearth/librender.so
opt/googleearth/libinput_plugin.so
opt/googleearth/libflightsim.so
opt/googleearth/libcollada.so
opt/googleearth/libminizip.so
opt/googleearth/libauth.so
opt/googleearth/libbasicingest.so
opt/googleearth/libmeasure.so
opt/googleearth/libgoogleearth_lib.so
opt/googleearth/libmoduleframework.so
"
QA_DT_HASH="opt/${PN}/.*"
pkg_setup() {
GCC_VER="$(gcc-version)"
if ! version_is_at_least ${GCC_NEEDED} ${GCC_VER}; then
ewarn "${PN} needs libraries from gcc-${GCC_NEEDED} or higher to run"
ewarn "Your active gcc version is only ${GCC_VER}"
ewarn "Please consult the GCC upgrade guide to set a higher version:"
ewarn "http://www.gentoo.org/doc/en/gcc-upgrading.xml"
fi
}
src_unpack() {
unpack_makeself
}
src_prepare() {
# make the postinst script only create the files; it's installation
# are too complicated and inserting them ourselves is easier than
# hacking around it
sed -i -e 's:$SETUP_INSTALLPATH/::' \
-e 's:$SETUP_INSTALLPATH:1:' \
-e "s:^xdg-desktop-icon.*$::" \
-e "s:^xdg-desktop-menu.*$::" \
-e "s:^xdg-mime.*$::" postinstall.sh
}
src_install() {
make_wrapper ${PN} ./${PN} /opt/${PN} . || die "make_wrapper failed"
./postinstall.sh
insinto /usr/share/mime/packages
doins ${PN}-mimetypes.xml
domenu Google-${PN}.desktop
doicon ${PN}-icon.png
dodoc README.linux
cd bin
tar xf "${WORKDIR}"/${PN}-linux-x86.tar
# bug #262780
epatch "${FILESDIR}/decimal-separator.patch"
exeinto /opt/${PN}
doexe *
cd "${D}"/opt/${PN}
tar xf "${WORKDIR}"/${PN}-data.tar
if ! use qt-bundled; then
rm -rvf libQt{Core,Gui,Network,WebKit}.so.4 plugins/imageformats qt.conf || die
fi
fowners -R root:root /opt/${PN}
fperms -R a-x,a+X /opt/googleearth/resources
}
pkg_postinst() {
fdo-mime_desktop_database_update
fdo-mime_mime_database_update
}
|
GitWeb