blob: 7b9def11a5b7b6b2be4c913cc321ee8a752bb47c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
|
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/swift/swift-1.12.0.ebuild,v 1.1 2014/02/20 21:04:11 prometheanfire Exp $
EAPI=5
PYTHON_COMPAT=( python2_7 )
inherit distutils-r1 eutils linux-info user
DESCRIPTION="A highly available, distributed, eventually consistent object/blob store"
HOMEPAGE="https://launchpad.net/swift"
SRC_URI="http://launchpad.net/${PN}/icehouse/${PV}/+download/${P}.tar.gz"
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="proxy account container object test +memcache"
REQUIRED_USE="|| ( proxy account container object )"
DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
>=dev-python/pbr-0.5.21[${PYTHON_USEDEP}]
<dev-python/pbr-1.0[${PYTHON_USEDEP}]
test? ( ~dev-python/pep8-1.4.5[${PYTHON_USEDEP}]
~dev-python/pyflakes-0.7.2[${PYTHON_USEDEP}]
~dev-python/flake8-2.0[${PYTHON_USEDEP}]
>=dev-python/hacking-0.5.6[${PYTHON_USEDEP}]
<dev-python/hacking-0.6[${PYTHON_USEDEP}]
dev-python/nose[${PYTHON_USEDEP}]
dev-python/coverage[${PYTHON_USEDEP}]
dev-python/nosexcover[${PYTHON_USEDEP}]
dev-python/openstack-nose-plugin[${PYTHON_USEDEP}]
dev-python/nosehtmloutput[${PYTHON_USEDEP}]
~dev-python/pep8-1.4.5[${PYTHON_USEDEP}]
>=dev-python/mock-0.8.0[${PYTHON_USEDEP}]
>=dev-python/sphinx-1.1.2[${PYTHON_USEDEP}]
<dev-python/sphinx-1.2[${PYTHON_USEDEP}] )"
RDEPEND=">=dev-python/dnspython-1.9.4[${PYTHON_USEDEP}]
>=dev-python/eventlet-0.9.15[${PYTHON_USEDEP}]
>=dev-python/greenlet-0.3.1[${PYTHON_USEDEP}]
>=dev-python/netifaces-0.5[${PYTHON_USEDEP}]
>=dev-python/pastedeploy-1.3.3[${PYTHON_USEDEP}]
>=dev-python/simplejson-2.0.9[${PYTHON_USEDEP}]
dev-python/pyxattr[${PYTHON_USEDEP}]
dev-python/python-swiftclient[${PYTHON_USEDEP}]
memcache? ( net-misc/memcached )
net-misc/rsync[xattr]"
CONFIG_CHECK="~EXT3_FS_XATTR ~SQUASHFS_XATTR ~CIFS_XATTR ~JFFS2_FS_XATTR
~TMPFS_XATTR ~UBIFS_FS_XATTR ~EXT2_FS_XATTR ~REISERFS_FS_XATTR ~EXT4_FS_XATTR
~ZFS"
#PATCHES=( "${FILESDIR}/CVE-2014-0006-master.diff" )
pkg_setup() {
enewuser swift
enewgroup swift
}
src_prepare() {
sed -i 's/xattr/pyxattr/g' "${S}/swift.egg-info/requires.txt"
sed -i 's/xattr/pyxattr/g' "${S}/requirements.txt"
distutils-r1_python_prepare_all
}
src_test () {
# https://bugs.launchpad.net/swift/+bug/1249727
find . \( -name test_wsgi.py -o -name test_locale.py \) -delete || die
SKIP_PIP_INSTALL=1 PBR_VERSION=0.5.23 sh .unittests || die
}
python_install() {
distutils-r1_python_install
keepdir /etc/swift
insinto /etc/swift
newins "etc/swift.conf-sample" "swift.conf"
# newins "etc/swift-bench.conf-sample" "swift-bench.conf-sample"
newins "etc/rsyncd.conf-sample" "rsyncd.conf"
newins "etc/mime.types-sample" "mime.types-sample"
newins "etc/memcache.conf-sample" "memcache.conf-sample"
newins "etc/drive-audit.conf-sample" "drive-audit.conf-sample"
newins "etc/dispersion.conf-sample" "dispersion.conf-sample"
if use proxy; then
newinitd "${FILESDIR}/swift-proxy.initd" "swift-proxy"
newins "etc/proxy-server.conf-sample" "proxy-server.conf"
if use memcache; then
sed -i '/depend/a\
need memcached' "${D}/etc/init.d/swift-proxy"
fi
fi
if use account; then
newinitd "${FILESDIR}/swift-account.initd" "swift-account"
newins "etc/account-server.conf-sample" "account-server.conf"
fi
if use container; then
newinitd "${FILESDIR}/swift-container.initd" "swift-container"
newins "etc/container-server.conf-sample" "container-server.conf"
fi
if use object; then
newinitd "${FILESDIR}/swift-object.initd" "swift-object"
newins "etc/object-server.conf-sample" "object-server.conf"
newins "etc/object-expirer.conf-sample" "object-expirer.conf"
fi
fowners swift:swift "/etc/swift" || die "fowners failed"
}
pkg_postinst() {
elog "Openstack swift will default to using insecure http unless a"
elog "certificate is created in /etc/swift/cert.crt and the associated key"
elog "in /etc/swift/cert.key. These can be created with the following:"
elog " * cd /etc/swift"
elog " * openssl req -new -x509 -nodes -out cert.crt -keyout cert.key"
}
|
GitWeb