blob: fd417fb097391ba387f69a33c039a8acfda7573a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
|
# Copyright 2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
LLVM_COMPAT=( {16..18} )
inherit cargo llvm-r1
DESCRIPTION="Scrollable-tiling Wayland compositor"
HOMEPAGE="https://github.com/YaLTeR/niri"
SRC_URI="
https://github.com/YaLTeR/niri/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz
https://github.com/YaLTeR/niri/releases/download/v${PV}/${P}-vendored-dependencies.tar.xz
"
LICENSE="GPL-3+"
# Dependent crate licenses
LICENSE+="
Apache-2.0 Apache-2.0-with-LLVM-exceptions BSD-2 BSD ISC MIT MPL-2.0
Unicode-DFS-2016
"
SLOT="0"
KEYWORDS="~amd64"
IUSE="+dbus screencast systemd"
REQUIRED_USE="
screencast? ( dbus )
systemd? ( dbus )
"
DEPEND="
dev-libs/glib:2
dev-libs/libinput:=
dev-libs/wayland
media-libs/mesa
sys-auth/seatd:=
virtual/libudev:=
x11-libs/cairo
x11-libs/libxkbcommon
x11-libs/pango
x11-libs/pixman
screencast? (
media-video/pipewire:=
)
"
RDEPEND="${DEPEND}"
# Clang is required for bindgen
BDEPEND="
>=virtual/rust-1.72.0
screencast? ( $(llvm_gen_dep 'sys-devel/clang:${LLVM_SLOT}') )
"
ECARGO_VENDOR="${WORKDIR}/vendor"
QA_FLAGS_IGNORED="usr/bin/niri"
src_prepare() {
sed -i 's/^git =.*/version = "*"/' Cargo.toml || die
default
}
src_configure() {
local myfeatures=(
$(usev dbus)
$(usev screencast xdp-gnome-screencast)
$(usev systemd)
)
cargo_src_configure --no-default-features
}
src_install() {
cargo_src_install
dobin resources/niri-session
insinto /usr/lib/systemd/user
doins resources/niri{.service,-shutdown.target}
insinto /usr/share/wayland-sessions
doins resources/niri.desktop
insinto /usr/share/xdg-desktop-portal
doins resources/niri-portals.conf
}
|
GitWeb