dev-python/hatchling: add 1.9.0

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

2 files changed, 75 insertions, 0 deletions

diff --git a/dev-python/hatchling/Manifest b/dev-python/hatchling/Manifest
index fa1971eb1d57..5e163c0fc2d9 100644
--- a/dev-python/hatchling/Manifest
+++ b/dev-python/hatchling/Manifest
@@ -2,3 +2,4 @@ DIST hatch-hatchling-v1.6.0.gh.tar.gz 233428 BLAKE2B 5ce5a2a94c9021919f50f90a96f
 DIST hatch-hatchling-v1.7.1.gh.tar.gz 1471608 BLAKE2B 52d7d1f8a45f5dd6573676b8f6946b843c5368ba0b0a53d1a30d48c1087350eea54335fbc76816f334526238451ab8075586212386bb18edc0c3b3cfc5224b3c SHA512 dfffc8586ee3ff5c7f1f277be1e653efef70fca5377c12c16bb05c1deeb5cf5eccc5cd58d0923a32c7a8b3701621f6be881709bb836734170a08b103b841107f
 DIST hatch-hatchling-v1.8.0.gh.tar.gz 1524674 BLAKE2B a23e2e4c40dda4df45a2124499f1f566038a1a6b5631f453a1631fc322474a536e7d8bd0972d315c38a7a3cf97ef2839c998bb4310fc6123dc154d597e75eda3 SHA512 14772c8d6d3408f66e755b59d58f4c67e12c96665d556f647261dfa60e250c1b586bea2731aedcf24c6ede4c0dae132ea205516735509e9e1ccc9ef4bbd84a15
 DIST hatch-hatchling-v1.8.1.gh.tar.gz 1525669 BLAKE2B d1c33648eb202d57448f4f01d724361bce0db2ca25b1445f2c5bdec5f517f0ddfa961d07ff6d76ba7f326d1feae524a1f6600b563ad6f8bd504c7d00e1b1316d SHA512 d1878085adfd00e4efe7bbd5d70bf76e2d34bd42f0ef4dfc813088025dcc9d180605013a0acd9e24b3da86087dcf9bbb37be76528001034282f7a30a6ccbc20b
+DIST hatch-hatchling-v1.9.0.gh.tar.gz 252859 BLAKE2B 7fe0e06b26808ab47c8deead09744c32b2806327944ca799fe1b919ffe34227b7f51c0c5c7a7cad5b3a08b61acc10a0f9528048f3a4a45cf53efece64005fe9d SHA512 b99de517e6a049910e119fea9de667dc87782ff6400a8b730bb402c6337176f39a8e956d69e71561e413b80710b651421eb320d2b1b747b1818c97607c456c78
diff --git a/dev-python/hatchling/hatchling-1.9.0.ebuild b/dev-python/hatchling/hatchling-1.9.0.ebuild
new file mode 100644
index 000000000000..868dd0172a97
--- /dev/null
+++ b/dev-python/hatchling/hatchling-1.9.0.ebuild
@@ -0,0 +1,74 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_TESTED=( pypy3 python3_{8..11} )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
+
+inherit distutils-r1
+
+TAG=${P/-/-v}
+MY_P=hatch-${TAG}
+DESCRIPTION="Modern, extensible Python build backend"
+HOMEPAGE="
+	https://pypi.org/project/hatchling/
+	https://github.com/pypa/hatch/
+"
+SRC_URI="
+	https://github.com/pypa/hatch/archive/${TAG}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}/backend
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/editables-0.2[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+	>=dev-python/pathspec-0.9[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/tomli-1.2.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/atomicwrites[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+			dev-python/httpx[${PYTHON_USEDEP}]
+			dev-python/platformdirs[${PYTHON_USEDEP}]
+			dev-python/rich[${PYTHON_USEDEP}]
+			dev-python/tomli-w[${PYTHON_USEDEP}]
+			dev-python/virtualenv[${PYTHON_USEDEP}]
+		' "${PYTHON_TESTED[@]}")
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+		einfo "Skipping tests on ${EPYTHON}"
+		return
+	fi
+
+	local -x EPYTEST_DESELECT=(
+		# these run pip to install stuff
+		tests/backend/dep/test_core.py::test_dependency_found
+		tests/backend/dep/test_core.py::test_extra_met
+		tests/backend/dep/test_core.py::test_extra_no_dependencies
+		tests/backend/dep/test_core.py::test_extra_unmet
+		tests/backend/dep/test_core.py::test_unknown_extra
+		tests/backend/dep/test_core.py::test_version_unmet
+	)
+
+	# top-level "tests" directory contains tests both for hatch
+	# and hatchling
+	cd "${WORKDIR}/${MY_P}" || die
+	local -x PYTHONPATH="src:${PYTHONPATH}"
+	epytest tests/backend
+}