www-client/opera: Version 70.0.3728.144

Package-Manager: Portage-3.0.4, Repoman-3.0.1
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

2 files changed, 111 insertions, 0 deletions

diff --git a/www-client/opera/Manifest b/www-client/opera/Manifest
index 0d528e6bc97e..f7347b6f93e4 100644
--- a/www-client/opera/Manifest
+++ b/www-client/opera/Manifest
@@ -1 +1,2 @@
 DIST opera-stable_70.0.3728.133_amd64.deb 67377640 BLAKE2B 268869625c32c842e87e8f2294363684a134a8e6233ea0cd0ea6670ac3c76f10ab56d2318e9e6ccc669cfa55162ea63c25f667c93ee8dfd8fb9ae0063447bb7b SHA512 ab6f8f14670687c2fe40a938e68921edef583eeb74f33c7429203f5ab951f7e40d4021c25c431bde6a219b7eb184130489ba6b4bdf5c59e2831d61d55f52c899
+DIST opera-stable_70.0.3728.144_amd64.deb 67316628 BLAKE2B 9dc48927b026a9c488526b9853fb161366fec9b5867e1a423a01f1e1d84d596191d4649044ce7d271ddaa2f86c2da62a0e9e39bed3fdecae5dd15518ca0776a5 SHA512 0c2175cec658e4ccf5a6199143f2cd66a0317ba6ece18403a9310cabefca17e4d83948ea56f96fb3a547db2ed6b208aea13be204816fcf31c2325d3b0e997489
diff --git a/www-client/opera/opera-70.0.3728.144.ebuild b/www-client/opera/opera-70.0.3728.144.ebuild
new file mode 100644
index 000000000000..58c0be89c0ab
--- /dev/null
+++ b/www-client/opera/opera-70.0.3728.144.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+CHROMIUM_LANGS="
+	be bg bn ca cs da de el en-GB en-US es-419 es fil fi fr-CA fr hi hr hu id
+	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+
+"
+inherit chromium-2 multilib unpacker xdg-utils
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2014"
+SLOT="0"
+SRC_URI_BASE="
+	https://download1.operacdn.com/pub/
+	https://download2.operacdn.com/pub/
+	https://download3.operacdn.com/pub/
+	https://download4.operacdn.com/pub/
+"
+for uri in ${SRC_URI_BASE}; do
+SRC_URI+="
+	"${uri}${PN}/desktop/${PV}/linux/${PN}-stable_${PV}_amd64.deb"
+"
+done
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	media-libs/alsa-lib
+	media-libs/fontconfig
+	media-libs/freetype
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/libXScrnSaver
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/libnotify
+	x11-libs/pango[X]
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+
+src_unpack() {
+	unpack_deb ${A}
+}
+
+src_prepare() {
+	default
+
+	OPERA_HOME="usr/$(get_libdir)/${PN}"
+
+	case ${ARCH} in
+		amd64)
+			mv usr/lib/x86_64-linux-gnu usr/$(get_libdir) || die
+			rm -r usr/lib || die
+			;;
+	esac
+
+	rm usr/bin/${PN} || die
+
+	rm usr/share/doc/${PN}-stable/copyright || die
+	mv usr/share/doc/${PN}-stable usr/share/doc/${PF} || die
+	gunzip usr/share/doc/${PF}/changelog.gz || die
+
+	pushd "${OPERA_HOME}"/localization > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+}
+
+src_install() {
+	rm "${OPERA_HOME}"/${PN}_autoupdate || die
+	mv * "${D}" || die
+	dosym ../$(get_libdir)/${PN}/${PN} /usr/bin/${PN}
+	fperms 4711 /"${OPERA_HOME}"/opera_sandbox
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}