games-strategy/naev: add 0.11.2

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

2 files changed, 112 insertions, 0 deletions

diff --git a/games-strategy/naev/Manifest b/games-strategy/naev/Manifest
index 46d0730536dd..4a0f76fde1f2 100644
--- a/games-strategy/naev/Manifest
+++ b/games-strategy/naev/Manifest
@@ -1 +1,2 @@
 DIST naev-0.11.0-source.tar.xz 453620076 BLAKE2B 78663400adb556be35d30819aeb6b7aa6fc7eb4c2e66ed7bba7a786ed8b76b800865cd5669fea886cfdea9cdbb9eae1adc78967c9362ecd4dcfe69ff163e5f52 SHA512 697232d78979f66d118df054cd39c60d1c2c0225bfa027eeef239957780dcc7b82effda9160e130dc898584148ff7d8e07567e6bbf2a9909022d684c63182b2d
+DIST naev-0.11.2-source.tar.xz 453720596 BLAKE2B d02231626411df67facb65564257e2f22c1120737544ab1328834242791336bf8f1610738fa875480c351fcbdc38d74f5ca1b28c0b7e26c96da03e70780ff8fc SHA512 fa6178303fbd3f5371671d2c325c72a22cf9cab9d0d74c8ddd83b1e32878b45b256cc178b0c504d65791416fbfe94148c05c107528876cf9d4e242ea2ad81a8e
diff --git a/games-strategy/naev/naev-0.11.2.ebuild b/games-strategy/naev/naev-0.11.2.ebuild
new file mode 100644
index 000000000000..f01a82495b7b
--- /dev/null
+++ b/games-strategy/naev/naev-0.11.2.ebuild
@@ -0,0 +1,111 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-1 luajit )
+PYTHON_COMPAT=( python3_{10..12} )
+inherit lua-single meson python-any-r1 virtualx xdg
+
+DESCRIPTION="2D space trading and combat game, in a similar vein to Escape Velocity"
+HOMEPAGE="https://naev.org/"
+SRC_URI="https://github.com/naev/naev/releases/download/v${PV}/${P}-source.tar.xz"
+
+LICENSE="
+	GPL-3+
+	Apache-2.0 BSD BSD-2 CC-BY-2.0 CC-BY-3.0 CC-BY-4.0 CC-BY-SA-3.0
+	CC-BY-SA-4.0 CC0-1.0 GPL-2+ MIT OFL-1.1 public-domain
+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+# dlopen: libglvnd
+RDEPEND="
+	${LUA_DEPS}
+	dev-games/physfs
+	dev-libs/libpcre2:=
+	dev-libs/libunibreak:=
+	dev-libs/libxml2
+	media-libs/freetype:2
+	media-libs/libglvnd
+	media-libs/libsdl2[joystick,opengl,video]
+	media-libs/libvorbis
+	media-libs/openal
+	media-libs/sdl2-image[png,webp]
+	net-libs/enet:1.3=
+	sci-libs/cholmod
+	sci-libs/cxsparse
+	sci-libs/openblas
+	sci-libs/suitesparse
+	sci-mathematics/glpk:=
+	virtual/libintl
+"
+DEPEND="
+	${RDEPEND}
+	test? (
+		dev-games/physfs[zip]
+		media-libs/libsdl2[X]
+	)
+"
+BDEPEND="
+	$(python_gen_any_dep 'dev-python/pyyaml[${PYTHON_USEDEP}]')
+	sys-devel/gettext
+	doc? (
+		app-text/doxygen
+		dev-lua/ldoc
+		media-gfx/graphviz
+	)
+	test? (
+		media-libs/mesa[llvm]
+		x11-base/xorg-server[-minimal]
+	)
+"
+
+python_check_deps() {
+	python_has_version "dev-python/pyyaml[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	lua-single_pkg_setup
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	# use eclass' generated lua.pc first rather than as fallback
+	sed -i "s/'lua51'/'lua'/" meson.build || die
+
+	# don't probe OpenGL for tests (avoids sandbox violations, bug #829369),
+	# mesa[llvm] should ensure software rendering will work
+	sed -i "/subdir('glcheck')/d" test/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature doc docs_c)
+		$(meson_feature doc docs_lua)
+		$(meson_feature lua_single_target_luajit luajit)
+	)
+
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+src_install() {
+	local DOCS=( CHANGELOG Readme.md )
+	meson_src_install
+
+	if use doc; then
+		dodir /usr/share/doc/${PF}/html
+		mv "${ED}"/usr/{doc/naev/{c,lua},share/doc/${PF}/html} || die
+		rm -r "${ED}"/usr/doc || die
+	fi
+
+	rm -r "${ED}"/usr/share/doc/naev || die
+}