sys-apps/tuned: version bump, 2.18.0

requiere app-emulation/virt-what from spec
Include optional features (hdparm, dmidecode, iproute2)

Closes: https://github.com/gentoo/gentoo/pull/24149
Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: INODE64 <ffelix@inode64.com>
Signed-off-by: Yixun Lan <dlan@gentoo.org>

4 files changed, 92 insertions, 9 deletions

diff --git a/sys-apps/tuned/Manifest b/sys-apps/tuned/Manifest
index 71d63c7625cd..2e205cc48127 100644
--- a/sys-apps/tuned/Manifest
+++ b/sys-apps/tuned/Manifest
@@ -1,2 +1,3 @@
 DIST tuned-2.16.0.tar.gz 213111 BLAKE2B 865cfffc89459396aa50c7908c88de405dea365084cf1592134391da961e88cc5610b663d93d531febdf881182624a13771493c61915003c59ad24bc64dd8a5c SHA512 35f04e1ee1ab3d8be711f0787db92c089cc210c75a3be0bc60389effaed8dc3fb502eff54ea0336154563f7b194f8ff286a2e408ab439a472b6d4922c64d5b03
 DIST tuned-2.17.0.tar.gz 214983 BLAKE2B 76c9609b91910cb5c4da67a18ba7d0c3dd7348e02360084ae6ca9e6b17832071314f5e4e84a4700789ae6c456aebb7c60c44e9951687d43a5e3a82fdbdddaa33 SHA512 e2521caa47c3176528ea1fd595d30c483aec4623eeccc9a7c1aa3b3781c7c9bdc48625488b313d7aaebbfecbae8f540029d2159d522574e334096094da54e868
+DIST tuned-2.18.0.tar.gz 218252 BLAKE2B 25bf078ea4e616830fa8b125251e24afbe2a566fcdd1050b2e1ac95125e22e8276b61f23a0236380bf1aec5ce892e1832230a800356460b5af21346c8825269d SHA512 9508bfad6502b7b9a72fb84d29308cbc10b3cb663b367c821e79ad4d57c2349086c199bf884440c46d230d08d0ad3df17d4f31ebdc03b68c7ba2695b6e18bcc9
diff --git a/sys-apps/tuned/tuned-2.16.0.ebuild b/sys-apps/tuned/tuned-2.16.0.ebuild
index cceedf446eba..7ce4188e8394 100644
--- a/sys-apps/tuned/tuned-2.16.0.ebuild
+++ b/sys-apps/tuned/tuned-2.16.0.ebuild
@@ -1,11 +1,11 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
 
 PYTHON_COMPAT=( python3_{8,9} )
 
-inherit python-single-r1 tmpfiles xdg-utils
+inherit optfeature python-single-r1 tmpfiles xdg-utils
 
 DESCRIPTION="Daemon for monitoring and adaptive tuning of system devices"
 HOMEPAGE="https://github.com/redhat-performance/tuned"
@@ -21,19 +21,21 @@ DEPEND="
 	${PYTHON_DEPS}
 	$(python_gen_cond_dep '
 		dev-python/configobj[${PYTHON_USEDEP}]
-		dev-python/decorator[${PYTHON_USEDEP}]
-		dev-python/pyudev[${PYTHON_USEDEP}]
 		dev-python/dbus-python[${PYTHON_USEDEP}]
+		dev-python/decorator[${PYTHON_USEDEP}]
 		dev-python/pygobject:3[${PYTHON_USEDEP}]
 		dev-python/python-linux-procfs[${PYTHON_USEDEP}]
+		dev-python/pyudev[${PYTHON_USEDEP}]
 	')"
 
 RDEPEND="
 	${DEPEND}
+	app-emulation/virt-what
+	dev-util/systemtap
 	sys-apps/dbus
 	sys-apps/ethtool
 	sys-power/powertop
-	dev-util/systemtap"
+	"
 
 RESTRICT="test"
 
@@ -60,4 +62,8 @@ src_install() {
 pkg_postinst() {
 	tmpfiles_process ${PN}.conf
 	xdg_icon_cache_update
+
+	optfeature_header
+	optfeature "Optimize for power saving by spinning-down rotational disks" sys-apps/hdparm
+	optfeature "Get hardware info" sys-apps/dmidecode
 }
diff --git a/sys-apps/tuned/tuned-2.17.0.ebuild b/sys-apps/tuned/tuned-2.17.0.ebuild
index d43f6e41ed30..ee2397ad3175 100644
--- a/sys-apps/tuned/tuned-2.17.0.ebuild
+++ b/sys-apps/tuned/tuned-2.17.0.ebuild
@@ -5,7 +5,7 @@ EAPI=8
 
 PYTHON_COMPAT=( python3_{8..10} )
 
-inherit python-single-r1 tmpfiles xdg-utils
+inherit optfeature python-single-r1 tmpfiles xdg-utils
 
 DESCRIPTION="Daemon for monitoring and adaptive tuning of system devices"
 HOMEPAGE="https://github.com/redhat-performance/tuned"
@@ -21,19 +21,21 @@ DEPEND="
 	${PYTHON_DEPS}
 	$(python_gen_cond_dep '
 		dev-python/configobj[${PYTHON_USEDEP}]
-		dev-python/decorator[${PYTHON_USEDEP}]
-		dev-python/pyudev[${PYTHON_USEDEP}]
 		dev-python/dbus-python[${PYTHON_USEDEP}]
+		dev-python/decorator[${PYTHON_USEDEP}]
 		dev-python/pygobject:3[${PYTHON_USEDEP}]
 		dev-python/python-linux-procfs[${PYTHON_USEDEP}]
+		dev-python/pyudev[${PYTHON_USEDEP}]
 	')"
 
 RDEPEND="
 	${DEPEND}
+	app-emulation/virt-what
+	dev-util/systemtap
 	sys-apps/dbus
 	sys-apps/ethtool
 	sys-power/powertop
-	dev-util/systemtap"
+	"
 
 RESTRICT="test"
 
@@ -60,4 +62,8 @@ src_install() {
 pkg_postinst() {
 	tmpfiles_process ${PN}.conf
 	xdg_icon_cache_update
+
+	optfeature_header
+	optfeature "Optimize for power saving by spinning-down rotational disks" sys-apps/hdparm
+	optfeature "Get hardware info" sys-apps/dmidecode
 }
diff --git a/sys-apps/tuned/tuned-2.18.0.ebuild b/sys-apps/tuned/tuned-2.18.0.ebuild
new file mode 100644
index 000000000000..8443e063fd1c
--- /dev/null
+++ b/sys-apps/tuned/tuned-2.18.0.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit optfeature python-single-r1 tmpfiles xdg-utils
+
+DESCRIPTION="Daemon for monitoring and adaptive tuning of system devices"
+HOMEPAGE="https://github.com/redhat-performance/tuned"
+SRC_URI="https://github.com/redhat-performance/tuned/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="
+	${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		dev-python/configobj[${PYTHON_USEDEP}]
+		dev-python/dbus-python[${PYTHON_USEDEP}]
+		dev-python/decorator[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		dev-python/python-linux-procfs[${PYTHON_USEDEP}]
+		dev-python/pyudev[${PYTHON_USEDEP}]
+	')"
+
+RDEPEND="
+	${DEPEND}
+	app-emulation/virt-what
+	dev-util/systemtap
+	sys-apps/dbus
+	sys-apps/ethtool
+	sys-power/powertop
+	"
+
+RESTRICT="test"
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e "/^PYTHON/s:/usr/bin/python3:${EPREFIX}/usr/bin/${EPYTHON}:" \
+		-e "/^export DOCDIR/s/$/&\-\$(VERSION)/g" \
+		-e "/\$(DESTDIR)\/run\/tuned/d" \
+		-e "/\$(DESTDIR)\/var\/lib\/tuned/d" \
+		-e "/\$(DESTDIR)\/var\/log\/tuned/d" \
+		Makefile || die
+}
+
+src_install() {
+	default
+
+	newinitd "${FILESDIR}/${PN}.initd" "${PN}"
+	python_fix_shebang "${D}"
+	python_optimize
+}
+
+pkg_postinst() {
+	tmpfiles_process ${PN}.conf
+	xdg_icon_cache_update
+
+	optfeature_header
+	optfeature "Optimize for power saving by spinning-down rotational disks" sys-apps/hdparm
+	optfeature "Get hardware info" sys-apps/dmidecode
+	optfeature "Optimize network txqueuelen" sys-apps/iproute2
+}