dev-python/notebook: Version Bump

Package-Manager: portage-2.2.26
Signed-off-by: Justin Lecher <jlec@gentoo.org>

2 files changed, 94 insertions, 0 deletions

diff --git a/dev-python/notebook/Manifest b/dev-python/notebook/Manifest
index 896c9f68e4e1..95e3280c95ca 100644
--- a/dev-python/notebook/Manifest
+++ b/dev-python/notebook/Manifest
@@ -1 +1,2 @@
 DIST notebook-4.0.6.tar.gz 6705277 SHA256 f62e7a6afbc00bab3615b927595d27b1874cff3218bddcbab62f97f6dae567c3 SHA512 9ce9ca21adcb967725aeb7a18543ace8aca4e88497d3d2fd708a603511e8ef4a932b39337d134d684df03b273bbc442958a37ced8cd499cb7b97a1c29758eeb0 WHIRLPOOL 764afabfa220d37e048a359952bd9cc4de0b791de782ed7cf2a22e8c0e9719b39630fd5c1c7acbf163715924662805f92b406bf6198600f2c4a35d239a12df11
+DIST notebook-4.1.0.tar.gz 9170981 SHA256 b597437ba33538221008e21fea71cd01eda9da1515ca3963d7c74e44f4b03d90 SHA512 745e412a737835956dc4238f70dbaf9c519fea55988941174febdc3ad24962031c3c66cb4ac355a9a639f9a383905e863e8eb0a3c6da62bf72026282154874cb WHIRLPOOL a34501e8e0be300905628e0f0df6914e8491a00924150ff0f5f32d1b7ad99046b84958dc267a229797fb13c98085f7556496a1a8e5fb68a1db503b44cad2b380
diff --git a/dev-python/notebook/notebook-4.1.0.ebuild b/dev-python/notebook/notebook-4.1.0.ebuild
new file mode 100644
index 000000000000..e2b503c3af77
--- /dev/null
+++ b/dev-python/notebook/notebook-4.1.0.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{3,4,5} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Jupyter Interactive Notebook"
+HOMEPAGE="http://jupyter.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+RDEPEND="
+	>=dev-libs/mathjax-2.4
+	dev-python/jinja[${PYTHON_USEDEP}]
+	>=dev-python/terminado-0.3.3[${PYTHON_USEDEP}]
+	>=www-servers/tornado-4.0[${PYTHON_USEDEP}]
+	dev-python/ipython_genutils[${PYTHON_USEDEP}]
+	dev-python/traitlets[${PYTHON_USEDEP}]
+	dev-python/jupyter_core[${PYTHON_USEDEP}]
+	dev-python/jupyter_client[${PYTHON_USEDEP}]
+	dev-python/nbformat[${PYTHON_USEDEP}]
+	dev-python/nbconvert[${PYTHON_USEDEP}]
+	dev-python/ipykernel[${PYTHON_USEDEP}]
+	"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python2_7)
+		>=dev-python/nose-0.10.1[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/coverage[${PYTHON_USEDEP}]
+	)
+	doc? (
+		app-text/pandoc
+		>=dev-python/ipython-4.0.0[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.1[${PYTHON_USEDEP}]
+	)
+	"
+
+python_prepare_all() {
+	sed \
+		-e "/import setup/s:$:\nimport setuptools:g" \
+		-i setup.py || die
+
+	# disable bundled mathjax
+	sed -i 's/^.*MathJax.*$//' bower.json || die
+	sed -i 's/mj(/#mj(/' setupbase.py || die
+
+	# Prevent un-needed download during build
+	if use doc; then
+		sed \
+			-e "/^    'sphinx.ext.intersphinx',/d" \
+			-i docs/source/conf.py || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	nosetests \
+		--verbosity=3 \
+		notebook || die
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	ln -sf \
+		"${EPREFIX}/usr/share/mathjax" \
+		"${D}$(python_get_sitedir)/notebook/static/components/MathJax" || die
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( docs/build/html/. )
+	distutils-r1_python_install_all
+}
+
+pkg_preinst() {
+	# remove old mathjax folder if present
+	rm -rf "${EROOT}"/usr/lib*/python*/site-packages/notebook/static/components/MathJax
+}