games-fps/etqw-data: Stop using games.eclass

Package-Manager: Portage-2.3.67, Repoman-2.3.14
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

2 files changed, 53 insertions, 65 deletions

diff --git a/games-fps/etqw-data/etqw-data-1.0-r1.ebuild b/games-fps/etqw-data/etqw-data-1.0-r1.ebuild
new file mode 100644
index 000000000000..6f5806dd98a1
--- /dev/null
+++ b/games-fps/etqw-data/etqw-data-1.0-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit cdrom
+
+DESCRIPTION="Enemy Territory: Quake Wars data files"
+HOMEPAGE="http://zerowing.idsoftware.com/linux/etqw/ETQWFrontPage/"
+SRC_URI=""
+
+LICENSE="ETQW"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86"
+IUSE="videos"
+
+S="${WORKDIR}"
+
+src_install() {
+	local dir=/opt/etqw
+
+	cdrom_get_cds Setup/Data/base/DEU:Setup/Data/base/POL:Setup/Data/base
+
+	cd "${CDROM_ROOT}"/Setup/Data/base
+	insinto "${dir}"/base
+	doins pak00{0..4}.pk4
+	doins -r megatextures
+
+	case ${CDROM_SET} in
+		0)
+			doins \
+				zpak_english000.pk4 \
+				DEU/zpak_german000.pk4 \
+				ESP/zpak_spanish000.pk4 \
+				FRA/zpak_french000.pk4
+			;;
+		1)
+			doins \
+				POL/zpak_polish000.pk4 \
+				RUS/zpak_russian000.pk4
+			;;
+		2)
+			doins zpak_english000.pk4
+			;;
+	esac
+
+	if use videos ; then
+		case ${CDROM_SET} in
+			0|2)
+				doins -r video
+				;;
+		esac
+	fi
+}
diff --git a/games-fps/etqw-data/etqw-data-1.0.ebuild b/games-fps/etqw-data/etqw-data-1.0.ebuild
deleted file mode 100644
index 048efa9cd245..000000000000
--- a/games-fps/etqw-data/etqw-data-1.0.ebuild
+++ /dev/null
@@ -1,65 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=0
-
-inherit eutils cdrom games
-
-DESCRIPTION="Enemy Territory: Quake Wars data files"
-HOMEPAGE="http://zerowing.idsoftware.com/linux/etqw/"
-SRC_URI=""
-
-LICENSE="ETQW"
-SLOT="0"
-KEYWORDS="-* ~amd64 ~x86"
-IUSE="videos"
-
-S=${WORKDIR}
-
-src_install() {
-	local dir=${GAMES_PREFIX_OPT}/etqw
-
-	cdrom_get_cds Setup/Data/base/DEU:Setup/Data/base/POL:Setup/Data/base
-
-	cd "${CDROM_ROOT}"/Setup/Data/base
-	insinto "${dir}"/base
-	doins pak00{0..4}.pk4 || die "doins pak failed"
-	doins -r megatextures || die "doins megatextures failed"
-
-	case ${CDROM_SET} in
-		0)
-			doins \
-				zpak_english000.pk4 \
-				DEU/zpak_german000.pk4 \
-				ESP/zpak_spanish000.pk4 \
-				FRA/zpak_french000.pk4 \
-				|| die "doins zpak failed"
-			;;
-		1)
-			doins \
-				POL/zpak_polish000.pk4 \
-				RUS/zpak_russian000.pk4 \
-				|| die "doins zpak failed"
-			;;
-		2)
-			doins zpak_english000.pk4 || die "doins zpak failed"
-			;;
-	esac
-
-	if use videos ; then
-		case ${CDROM_SET} in
-			0|2)
-				doins -r video || die "doins video failed"
-				;;
-		esac
-	fi
-
-	prepgamesdirs
-}
-
-pkg_postinst() {
-	games_pkg_postinst
-
-	elog "This is just the data portion of the game. You will need to install"
-	elog "games-fps/etqw-bin to play it."
-}