dev-python/astroid: Bump to 3.3.6

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 90 insertions, 0 deletions

diff --git a/dev-python/astroid/Manifest b/dev-python/astroid/Manifest
index aaa208ad44cd..4a45615e7c8e 100644
--- a/dev-python/astroid/Manifest
+++ b/dev-python/astroid/Manifest
@@ -1 +1,2 @@
 DIST astroid-3.3.5.gh.tar.gz 465885 BLAKE2B 64453a7b17aa1584083ca3c1fea4fdf8a236a1e0b80a66d8fe83a7201f2ef7c1cb362370648d61f766e8dc101c7797fbb7c5a2ab6f21e23da3830072e6a66c23 SHA512 323774d0853e8bebf5074eab3da3c29dfd2c04c96f222eb9a7fbe8da37544f7e6dceed8d0fd163591a2cd56a3d06ebf8ec33d23baeb921aa49cccb0f29cae426
+DIST astroid-3.3.6.gh.tar.gz 466233 BLAKE2B 6b8bebeb7f56009d6ea7749f911a309e6cd2a0a7bac7ade1ea91ca74bc157f048c3652a50321a72c961670cb8dcc8f584bd39ef8a2d82408b4be27c8efcbdb58 SHA512 7ed2900cdf563cb761596cb816452e64be131c34d7ea7eedb27a5ceac4e588c3c675deba72bee17557c408c019e489c6f1e86772bdc235e2f1b048239b76c993
diff --git a/dev-python/astroid/astroid-3.3.6.ebuild b/dev-python/astroid/astroid-3.3.6.ebuild
new file mode 100644
index 000000000000..adfa5e854419
--- /dev/null
+++ b/dev-python/astroid/astroid-3.3.6.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{10..13} )
+
+inherit distutils-r1
+
+DESCRIPTION="Abstract Syntax Tree for logilab packages"
+HOMEPAGE="
+	https://github.com/pylint-dev/astroid/
+	https://pypi.org/project/astroid/
+"
+SRC_URI="
+	https://github.com/pylint-dev/astroid/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+# Version specified in pyproject.toml
+RDEPEND="
+	$(python_gen_cond_dep '
+		>=dev-python/typing-extensions-4.0.0[${PYTHON_USEDEP}]
+	' 3.10)
+"
+# dev-python/regex isn't available for pypy
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/attrs[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.17.0[${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/regex[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# no clue why they're broken
+		tests/test_modutils.py::GetModulePartTest::test_known_values_get_builtin_module_part
+		tests/test_regrtest.py::NonRegressionTests::test_numpy_distutils
+		# pydantic-2?
+		tests/brain/test_dataclasses.py::test_pydantic_field
+		# requires urllib3 with bundled six (skipped with urllib3>=2)
+		tests/test_modutils.py::test_file_info_from_modpath__SixMetaPathImporter
+		# hangs
+		tests/test_nodes.py::AsStringTest::test_recursion_error_trapped
+		# TODO
+		tests/test_builder.py::BuilderTest::test_data_build_error_filename
+		# numpy-2 (https://github.com/pylint-dev/astroid/issues/2442)
+		tests/brain/numpy/test_core_einsumfunc.py::test_numpy_function_calls_inferred_as_ndarray
+		tests/brain/numpy/test_core_fromnumeric.py::BrainNumpyCoreFromNumericTest::test_numpy_function_calls_inferred_as_ndarray
+		tests/brain/numpy/test_core_multiarray.py::BrainNumpyCoreMultiarrayTest::test_numpy_function_calls_inferred_as_ndarray
+		tests/brain/numpy/test_core_numerictypes.py::NumpyBrainCoreNumericTypesTest::test_datetime_astype_return
+		tests/brain/numpy/test_core_numerictypes.py::NumpyBrainCoreNumericTypesTest::test_generic_types_are_subscriptables
+		tests/brain/numpy/test_core_umath.py::NumpyBrainCoreUmathTest::test_numpy_core_umath_functions_return_type
+		tests/brain/numpy/test_core_umath.py::NumpyBrainCoreUmathTest::test_numpy_core_umath_functions_return_type_tuple
+	)
+
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				tests/test_transforms.py::TestTransforms::test_transform_aborted_if_recursion_limited
+			)
+			;;
+		python3.13)
+			EPYTEST_DESELECT+=(
+				# changes in py3.13.0b4
+				# https://github.com/pylint-dev/astroid/issues/2478
+				tests/test_nodes.py::AsStringTest::test_f_strings
+				tests/test_nodes_lineno.py::TestLinenoColOffset::test_end_lineno_string
+			)
+			;;
+	esac
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}