app-crypt/tc-play: [QA] EAPI 8, fix useless multilib

Multilib is only ever used here in src_configure because
it's exported. The program isn't even built for multilib
(which is a good thing, or it'd be even more of a waste,
as it's not like it'd get installed anyway).

Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 60 insertions, 0 deletions

diff --git a/app-crypt/tc-play/tc-play-2.0-r2.ebuild b/app-crypt/tc-play/tc-play-2.0-r2.ebuild
new file mode 100644
index 000000000000..244696e5f144
--- /dev/null
+++ b/app-crypt/tc-play/tc-play-2.0-r2.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="A free, pretty much fully featured and stable TrueCrypt implementation"
+HOMEPAGE="https://github.com/bwalex/tc-play"
+SRC_URI="https://github.com/bwalex/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="gnutls"
+
+DEPEND="
+	dev-libs/libgcrypt:=
+	dev-libs/libgpg-error
+	sys-apps/util-linux
+	sys-fs/lvm2
+	gnutls? ( net-libs/gnutls )
+	!gnutls? (
+		dev-libs/openssl:=
+	)
+"
+RDEPEND="${DEPEND}"
+
+DOCS=( README.md )
+
+PATCHES=(
+	"${FILESDIR}/${P}-build.patch"
+)
+
+pkg_setup() {
+	local backend="openssl"
+	use gnutls && local backend="gcrypt"
+
+	EXTRA_MAKE_FLAGS=(
+		PBKDF_BACKEND="${backend}"
+		WARNFLAGS=""
+		CC="$(tc-getCC)"
+		AR="$(tc-getAR)"
+		PREFIX=/usr
+		LIBDIR=/usr/$(get_libdir)
+	)
+}
+
+src_compile() {
+	emake -f Makefile.classic \
+		tcplay \
+		"${EXTRA_MAKE_FLAGS[@]}"
+}
+
+src_install() {
+	emake -f Makefile.classic \
+		"${EXTRA_MAKE_FLAGS[@]}" \
+		install_program \
+		DESTDIR="${ED}"
+}