app-crypt/eid-mw: version bump 4.4.11, adjust live ebuild

- Add p11v220 use flag (PKCS11 standard version 2.20)
- Remove xpi obsolete useflag
Submitted-by: Vincent Hardy <vincent.hardy.be@gmail.com>

Signed-off-by: Amy Liffey <amynka@gentoo.org>
Package-Manager: Portage-2.3.49, Repoman-2.3.11

4 files changed, 111 insertions, 37 deletions

diff --git a/app-crypt/eid-mw/Manifest b/app-crypt/eid-mw/Manifest
index 39a3279d955b..debf3f3f29b3 100644
--- a/app-crypt/eid-mw/Manifest
+++ b/app-crypt/eid-mw/Manifest
@@ -1 +1,2 @@
 DIST eid-mw-4.4.1.tar.gz 7708697 BLAKE2B 7bdbaa37af1cdd5a8abd1519939f663c7c871cea49850932d97c391465de362885b061c024285ab2690473a4bb1ba57a70fdc12a720246b2a610ac9525f6395e SHA512 9de54858ac052eeff101070dd11c5cf60ab1d29b8dc8d946680745acf9aa6ba1044ca5451eca6066b5b467fbc32a2a23bbe7e8551ca7559e6003a4097a304cfc
+DIST eid-mw-4.4.11.tar.gz 7975630 BLAKE2B e7b052736cba98c53e97e9de15ea8e54f508c28471a7a936c5d28539648f5d3454983d9c9a21cf5959a070849865de5ca58d5d29ad64eb08209afd40959c56ae SHA512 35273492abc0efa7146848c82770bcd5e4ce1b7c9971ce45686b4d3244332456011db6df05154ad6a204854fd13ac3dce8f7b8cd6112a2e60a7b8434f3c4a196
diff --git a/app-crypt/eid-mw/eid-mw-4.4.11.ebuild b/app-crypt/eid-mw/eid-mw-4.4.11.ebuild
new file mode 100644
index 000000000000..e496d37797e7
--- /dev/null
+++ b/app-crypt/eid-mw/eid-mw-4.4.11.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools gnome2-utils
+
+DESCRIPTION="Electronic Identity Card middleware supplied by the Belgian Federal Government"
+HOMEPAGE="https://eid.belgium.be"
+SRC_URI="https://codeload.github.com/fedict/${PN}/tar.gz/v${PV} -> ${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="+dialogs +gtk +p11v220 p11-kit"
+
+RDEPEND=">=sys-apps/pcsc-lite-1.2.9
+	gtk? (
+		x11-libs/gdk-pixbuf[jpeg]
+		x11-libs/gtk+:*
+		dev-libs/libxml2
+		net-misc/curl[ssl]
+		net-libs/libproxy
+		!app-misc/eid-viewer-bin
+	)
+	p11-kit? ( app-crypt/p11-kit )"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+REQUIRED_USE="dialogs? ( gtk )"
+
+src_prepare() {
+	default
+
+	sed -i -e 's:/beid/rsaref220:/rsaref220:' configure.ac || die
+	sed -i -e 's:/beid::' cardcomm/pkcs11/src/libbeidpkcs11.pc.in || die
+
+	# Buggy internal versioning when autoreconf a tarball release.
+	# Weird numbering is required otherwise we get a seg fault in
+	# about-eid-mw program.
+	echo "${PV}-v${PV}" > .version
+	sed -i \
+		-e '/^GITDESC/ d' \
+		-e '/^VERCLEAN/ d' \
+		scripts/build-aux/genver.sh
+
+	# legacy xpi module : we don't want it anymore
+	sed -i -e '/SUBDIRS/ s:plugins_tools/xpi ::' Makefile.am || die
+	sed -i -e '/plugins_tools\/xpi/ d' configure.ac || die
+
+	# hardcoded lsb_info
+	sed -i \
+		-e "s:get_lsb_info('i'):strdup(_(\"Gentoo\")):" \
+		-e "s:get_lsb_info('r'):strdup(_(\"n/a\")):" \
+		-e "s:get_lsb_info('c'):strdup(_(\"n/a\")):" \
+		plugins_tools/aboutmw/gtk/about-main.c || die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable dialogs) \
+		$(use_enable p11v220) \
+		$(use_enable p11-kit p11kit) \
+		$(use_with gtk gtkvers 'detect') \
+		--with-gnu-ld \
+		--disable-static
+}
+
+src_install() {
+	default
+	rm -r "${ED}"/usr/$(get_libdir)/*.la || die
+	if use gtk; then
+		domenu plugins_tools/eid-viewer/eid-viewer.desktop
+		doicon plugins_tools/eid-viewer/gtk/eid-viewer.png
+	fi
+}
+
+pkg_postinst(){
+	if use gtk; then
+		gnome2_schemas_update
+		gnome2_icon_cache_update
+	fi
+}
+
+pkg_postrm(){
+	if use gtk; then
+		gnome2_schemas_update
+		gnome2_icon_cache_update
+	fi
+}
diff --git a/app-crypt/eid-mw/eid-mw-9999.ebuild b/app-crypt/eid-mw/eid-mw-9999.ebuild
index 9c2c887e6186..4f93816f0b92 100644
--- a/app-crypt/eid-mw/eid-mw-9999.ebuild
+++ b/app-crypt/eid-mw/eid-mw-9999.ebuild
@@ -1,25 +1,17 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
 
-inherit autotools mozextension gnome2-utils
-
-if [[ ${PV} == "9999" ]] ; then
-	EGIT_REPO_URI="https://github.com/Fedict/${PN}.git"
-	inherit git-r3
-	SRC_URI=""
-else
-	SRC_URI="https://codeload.github.com/fedict/${PN}/tar.gz/v${PV} -> ${P}.tar.gz"
-	KEYWORDS="~x86 ~amd64 ~arm"
-fi
+inherit autotools gnome2-utils git-r3
 
 DESCRIPTION="Electronic Identity Card middleware supplied by the Belgian Federal Government"
 HOMEPAGE="https://eid.belgium.be"
+EGIT_REPO_URI="https://github.com/Fedict/${PN}.git"
 
 LICENSE="LGPL-3"
 SLOT="0"
-IUSE="+dialogs +gtk p11-kit +xpi"
+IUSE="+dialogs +gtk +p11v220 p11-kit"
 
 RDEPEND=">=sys-apps/pcsc-lite-1.2.9
 	gtk? (
@@ -30,9 +22,7 @@ RDEPEND=">=sys-apps/pcsc-lite-1.2.9
 		net-libs/libproxy
 		!app-misc/eid-viewer-bin
 	)
-	p11-kit? ( app-crypt/p11-kit )
-	xpi? ( || ( >=www-client/firefox-bin-3.6.24
-		>=www-client/firefox-3.6.20 ) )"
+	p11-kit? ( app-crypt/p11-kit )"
 
 DEPEND="${RDEPEND}
 	virtual/pkgconfig"
@@ -45,6 +35,10 @@ src_prepare() {
 	sed -i -e 's:/beid/rsaref220:/rsaref220:' configure.ac || die
 	sed -i -e 's:/beid::' cardcomm/pkcs11/src/libbeidpkcs11.pc.in || die
 
+	# legacy xpi module : we don't want it anymore
+	sed -i -e '/SUBDIRS/ s:plugins_tools/xpi ::' Makefile.am || die
+	sed -i -e '/plugins_tools\/xpi/ d' configure.ac || die
+
 	# hardcoded lsb_info
 	sed -i \
 		-e "s:get_lsb_info('i'):strdup(_(\"Gentoo\")):" \
@@ -58,33 +52,19 @@ src_prepare() {
 src_configure() {
 	econf \
 		$(use_enable dialogs) \
+		$(use_enable p11v220) \
 		$(use_enable p11-kit p11kit) \
 		$(use_with gtk gtkvers 'detect') \
 		--with-gnu-ld \
-		--disable-static \
-		--disable-signed
+		--disable-static
 }
 
 src_install() {
 	default
-
-	if use xpi; then
-		declare MOZILLA_FIVE_HOME
-		if has_version '>=www-client/firefox-3.6.20'; then
-			MOZILLA_FIVE_HOME="/usr/$(get_libdir)/firefox"
-			xpi_install "${ED}/usr/share/mozilla/extensions/{ec8030f7-c20a-464f-9b0e-13a3a9e97384}/{ec8030f7-c20a-464f-9b0e-13a3a9e97384}/belgiumeid@eid.belgium.be"
-		fi
-		if has_version '>=www-client/firefox-bin-3.6.24'; then
-			MOZILLA_FIVE_HOME="/opt/firefox"
-			xpi_install "${ED}/usr/share/mozilla/extensions/{ec8030f7-c20a-464f-9b0e-13a3a9e97384}/{ec8030f7-c20a-464f-9b0e-13a3a9e97384}/belgiumeid@eid.belgium.be"
-		fi
-	else
-		rm -r "${ED}"/usr/lib/mozilla || die
-	fi
-	rm -r "${ED}/usr/share/mozilla" "${ED}"/usr/$(get_libdir)/*.la || die
-
+	rm -r "${ED}"/usr/$(get_libdir)/*.la || die
 	if use gtk; then
-		rm -r "${ED}/usr/include/eid-util" || die
+		domenu plugins_tools/eid-viewer/eid-viewer.desktop
+		doicon plugins_tools/eid-viewer/gtk/eid-viewer.png
 	fi
 }
 
diff --git a/app-crypt/eid-mw/metadata.xml b/app-crypt/eid-mw/metadata.xml
index 5a0c5666c030..99549db6384a 100644
--- a/app-crypt/eid-mw/metadata.xml
+++ b/app-crypt/eid-mw/metadata.xml
@@ -25,11 +25,11 @@ These three functions form the basis of the countless applications for your eID.
   <flag name="dialogs">
     Enable "askaccess" dialog box, by using <pkg>x11-libs/gtk+</pkg>
   </flag>
-   <flag name="xpi">
-    Build and install an extension for Mozilla browsers.
-  </flag>
   <flag name="p11-kit">
     Support for app-crypt/p11-kit.
   </flag>
+  <flag name="p11v220">
+    Enable PKCS#11 v2.20 features.
+  </flag>
 </use>
 </pkgmetadata>