app-doc/devmanual: add 0_pre20220625

Signed-off-by: Ulrich Müller <ulm@gentoo.org>

2 files changed, 61 insertions, 0 deletions

diff --git a/app-doc/devmanual/Manifest b/app-doc/devmanual/Manifest
index 68009359ff24..0f08e214609c 100644
--- a/app-doc/devmanual/Manifest
+++ b/app-doc/devmanual/Manifest
@@ -1 +1,2 @@
 DIST devmanual-0_pre20220326.tar.xz 183228 BLAKE2B 67ab1a24e8f1043f2d7938a76f4d819ecfaffaf3516cf5ce9eff20ac0e481c60be06c83c4adc3835e6ee66c44def290aa682567662dbf7a7a7057b0d168e1677 SHA512 364fe3504ba424201b450e08fe2043e55d1067c3603c4d3248112117461a4ab667d50f82deac9daaf50e28ea5d996c1ae08668d55b7379915cc175f66edddf9b
+DIST devmanual-0_pre20220625.tar.xz 185236 BLAKE2B 3fb6bc0ec184c611fb10aa3062ffc7cd12e1d77a5a093fd13f7958fbf3494c42dc9674e10164c67080d1b5af1dcdc2fa09c017aeaec77e09fdd87cf63556b4c8 SHA512 46f44a9d77b0f433b9f8bbe48f1a2c9871c00a78f9726b7bed8aebb1e389898e0ddcbcee313ff277fc3946b3b2d46b5a23227c4f6d41cee467605086c182ba56
diff --git a/app-doc/devmanual/devmanual-0_pre20220625.ebuild b/app-doc/devmanual/devmanual-0_pre20220625.ebuild
new file mode 100644
index 000000000000..f4df71ec1d10
--- /dev/null
+++ b/app-doc/devmanual/devmanual-0_pre20220625.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="xml"
+inherit python-any-r1 readme.gentoo-r1
+
+DESCRIPTION="The Gentoo Development Guide"
+HOMEPAGE="https://devmanual.gentoo.org/"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/devmanual.git"
+else
+	# "make dist" in devmanual repo
+	SRC_URI="https://dev.gentoo.org/~ulm/distfiles/${P}.tar.xz"
+	S="${WORKDIR}/${PN}"
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+fi
+
+LICENSE="CC-BY-SA-4.0"
+SLOT="0"
+IUSE="+offline test"
+RESTRICT="!test? ( test )"
+
+BDEPEND=">=dev-libs/libxml2-2.9.12
+	dev-libs/libxslt
+	gnome-base/librsvg
+	media-fonts/open-sans
+	${PYTHON_DEPS}
+	test? ( >=app-text/htmltidy-5.8.0 )"
+
+PATCHES=( "${FILESDIR}"/${PN}-eclasses.patch )
+
+src_compile() {
+	emake OFFLINE=$(usex offline 1 0)
+}
+
+src_install() {
+	emake OFFLINE=$(usex offline 1 0) \
+		DESTDIR="${D}" \
+		htmldir="${EPREFIX}"/usr/share/doc/${PF}/html \
+		install
+
+	local DOC_CONTENTS="In order to browse the Gentoo Development Guide in
+		offline mode, point your browser to the following url:
+		file://${EPREFIX}/usr/share/doc/${PF}/html/index.html"
+	if ! has_version app-doc/eclass-manpages; then
+		DOC_CONTENTS+="\\n\\nThe offline version of the devmanual does not
+			include the documentation for the eclasses. If you need it,
+			then emerge app-doc/eclass-manpages."
+	fi
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+}