app-emacs/cider: new package; add 1.5.0

Signed-off-by: Maciej Barć <xgqt@gentoo.org>

4 files changed, 73 insertions, 0 deletions

diff --git a/app-emacs/cider/Manifest b/app-emacs/cider/Manifest
new file mode 100644
index 000000000000..fcb6c206c9d6
--- /dev/null
+++ b/app-emacs/cider/Manifest
@@ -0,0 +1 @@
+DIST cider-1.5.0.tar.gz 6709101 BLAKE2B 0baf8345201b61e99bb279dc6378dd15052c01f32842f98fd756438a173e45f82a061a853a0a453801c6ebdb0d0bc4a2a199d06c08b2413315568348ae1d8ca4 SHA512 48874bfe54d31b7bf52c56390aab307603b913e6bc717138450a5b49b3ab4c5dea7d031a6f699a8f04d7e43a1dd67fa604c06532d58634949579bf0a6089594b
diff --git a/app-emacs/cider/cider-1.5.0.ebuild b/app-emacs/cider/cider-1.5.0.ebuild
new file mode 100644
index 000000000000..86486ffa8584
--- /dev/null
+++ b/app-emacs/cider/cider-1.5.0.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+NEED_EMACS=26
+
+inherit elisp optfeature
+
+DESCRIPTION="Clojure Interactive Development Environment for GNU Emacs"
+HOMEPAGE="https://github.com/clojure-emacs/cider/"
+SRC_URI="https://github.com/clojure-emacs/${PN}/archive/v${PV}.tar.gz
+	-> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+KEYWORDS="~amd64"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-emacs/clojure-mode
+	app-emacs/parseedn
+	app-emacs/queue
+	app-emacs/sesman
+	app-emacs/spinner
+"
+BDEPEND="
+	${RDEPEND}
+	test? ( app-emacs/buttercup )
+"
+
+ELISP_REMOVE="test/${PN}-jar-test.el"
+DOCS=( CHANGELOG.md README.md ROADMAP.md refcard )
+SITEFILE="50${PN}-gentoo.el"
+
+src_test() {
+	buttercup -L . -L test --traceback full || die "tests failed"
+}
+
+src_install() {
+	elisp_src_install
+
+	optfeature "Connecting to leiningen REPL"               \
+		dev-java/leiningen dev-java/leiningen-bin
+}
diff --git a/app-emacs/cider/files/50cider-gentoo.el b/app-emacs/cider/files/50cider-gentoo.el
new file mode 100644
index 000000000000..298d184202ef
--- /dev/null
+++ b/app-emacs/cider/files/50cider-gentoo.el
@@ -0,0 +1,5 @@
+(add-to-list 'load-path "@SITELISP@")
+(autoload 'cider "cider"
+  "Start a connection of any type interactively." t)
+(autoload 'cider-mode "cider-mode"
+  "Minor mode for REPL interaction from a Clojure buffer." t)
diff --git a/app-emacs/cider/metadata.xml b/app-emacs/cider/metadata.xml
new file mode 100644
index 000000000000..acd2ef65fb80
--- /dev/null
+++ b/app-emacs/cider/metadata.xml
@@ -0,0 +1,21 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+
+<pkgmetadata>
+  <maintainer type="project">
+    <email>gnu-emacs@gentoo.org</email>
+    <name>Gentoo GNU Emacs project</name>
+  </maintainer>
+  <longdescription>
+    CIDER extends Emacs with support for interactive programming in Clojure.
+    The features are centered around cider-mode, an Emacs minor-mode that
+    complements clojure-mode. While clojure-mode supports editing Clojure
+    source files, cider-mode adds support for interacting with a running
+    Clojure process for compilation, code completion, debugging, definition and
+    documentation lookup, running tests and so on.
+  </longdescription>
+  <upstream>
+    <bugs-to>https://github.com/clojure-emacs/cider/issues/</bugs-to>
+    <remote-id type="github">clojure-emacs/cider</remote-id>
+  </upstream>
+</pkgmetadata>