app-i18n/ibus: Version bump to 1.5.29

* Add a REQUIRED_USE rule to avoid a build failure (bug #915359)

Closes: https://bugs.gentoo.org/915359
Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 235 insertions, 0 deletions

diff --git a/app-i18n/ibus/Manifest b/app-i18n/ibus/Manifest
index 7ebe4dbade5d..60ec683629d8 100644
--- a/app-i18n/ibus/Manifest
+++ b/app-i18n/ibus/Manifest
@@ -3,3 +3,4 @@ DIST ibus-1.5.27.tar.gz 3779541 BLAKE2B e98f775cd62036ae02dafd984933343e99390a6a
 DIST ibus-1.5.28-upstream-patches-0.tar.xz 23820 BLAKE2B 773736257e166170060458ad66b99889d2e54ef480504fe86ee65bc41364243ddcb5c7625aaa66a3e266c735d024c4f6c51d559484214d1f1c04a30479ccba62 SHA512 5555162bcb129f9e07c135c921c778de080aeaec81d56bedcf62d3b568cf39515e41662790c5a3d34241586d58785b887bbbaa7a75f486338968e3a496aa6433
 DIST ibus-1.5.28.tar.gz 3871246 BLAKE2B 7117c09e708df8a08e6684cc1096f38873503eb2c7937e0e3b02aeff678c96b3e2fc59fa4dfc7a11275b2e1b3349ae136041f8f4730aadc66339914b77c577d3 SHA512 5bfb9158a5810d38af900775ed30406823872c431ef4772b476afa7b58c120ef508a51b961620ea6003549f1f49cf05484992beee8677b138f1162afc73ab247
 DIST ibus-1.5.29-rc1.tar.gz 3989492 BLAKE2B c99f42fcd18bed240bf5e9f5b406bc879b05b12f3d0c14713e21b8c99fbcde32cd880dead1374731914289c022b1f160d9961bdbd9e9a0a3ced86949c5beb811 SHA512 776a01bcfd730be67e0f7d730f7b4b0a586d39744deb605359330a1786542acae52efbc085c39b8417b20164e45c259b40b29725f53fb1b69e2b340778ff28dc
+DIST ibus-1.5.29-rc2.tar.gz 3991416 BLAKE2B c185c0cf8af79a80ee04f414e13c4b58bd2f18891851d2f018713848b3bc0fe0516c8c0cf8f64204040f10b6b4a5304c8be6305449d7290b5d08412246d3af40 SHA512 47dd39c9615783b6c157a25e8a2506dc2e1f440d56aa649ee8cb95a390cb4efab9c95e72ac84b5d042c25e350599b4d352ddc66f1385af6660d4a7a296e44ca7
diff --git a/app-i18n/ibus/ibus-1.5.29.ebuild b/app-i18n/ibus/ibus-1.5.29.ebuild
new file mode 100644
index 000000000000..6c46f5514b9c
--- /dev/null
+++ b/app-i18n/ibus/ibus-1.5.29.ebuild
@@ -0,0 +1,234 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit autotools bash-completion-r1 gnome2-utils python-r1 toolchain-funcs vala virtualx
+
+DESCRIPTION="Intelligent Input Bus for Linux / Unix OS"
+HOMEPAGE="https://github.com/ibus/ibus/wiki"
+
+MY_PV=$(ver_rs 3 '-')
+MY_PV_DERP="${MY_PV}-rc2" # Upstream retagged rc2 as the final release
+GENTOO_VER=
+[[ -n ${GENTOO_VER} ]] && \
+	GENTOO_PATCHSET_URI="https://dev.gentoo.org/~dlan/distfiles/${P}-gentoo-patches-${GENTOO_VER}.tar.xz"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/${MY_PV}/${PN}-${MY_PV_DERP}.tar.gz
+	${GENTOO_PATCHSET_URI}"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="X appindicator +emoji gtk2 +gtk3 +gtk4 +gui +introspection libnotify nls +python systemd test +unicode vala wayland"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="
+	appindicator? ( gtk3 )
+	python? (
+		${PYTHON_REQUIRED_USE}
+		introspection
+	)
+	test? ( gtk3 )
+	vala? ( introspection )
+	X? ( gtk3 )
+"
+REQUIRED_USE+=" gtk3? ( wayland? ( introspection ) )" # bug 915359
+DEPEND="
+	app-text/iso-codes
+	>=dev-libs/glib-2.65.0:2
+	gnome-base/dconf
+	gnome-base/librsvg:2
+	sys-apps/dbus[X?]
+	X? (
+		x11-libs/libX11
+		>=x11-libs/libXfixes-6.0.0
+	)
+	appindicator? ( dev-libs/libdbusmenu[gtk3?] )
+	gtk2? ( x11-libs/gtk+:2 )
+	gtk3? ( x11-libs/gtk+:3 )
+	gtk4? ( gui-libs/gtk:4 )
+	gui? (
+		x11-libs/libX11
+		x11-libs/libXi
+	)
+	introspection? ( dev-libs/gobject-introspection )
+	libnotify? ( x11-libs/libnotify )
+	nls? ( virtual/libintl )
+	python? (
+		${PYTHON_DEPS}
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	)
+	wayland? (
+		dev-libs/wayland
+		x11-libs/libxkbcommon
+	)"
+RDEPEND="${DEPEND}
+	python? (
+		gui? (
+			x11-libs/gtk+:3[introspection]
+		)
+	)"
+BDEPEND="
+	$(vala_depend)
+	dev-libs/glib:2
+	dev-util/glib-utils
+	virtual/pkgconfig
+	x11-misc/xkeyboard-config
+	emoji? (
+		app-i18n/unicode-cldr
+		app-i18n/unicode-emoji
+	)
+	nls? ( sys-devel/gettext )
+	test? ( x11-apps/setxkbmap )
+	unicode? ( app-i18n/unicode-data )"
+
+S=${WORKDIR}/${PN}-${MY_PV_DERP}
+
+src_prepare() {
+	vala_setup --ignore-use
+	if ! has_version 'x11-libs/gtk+:3[wayland]'; then
+		touch ui/gtk3/panelbinding.vala \
+			ui/gtk3/panel.vala \
+			ui/gtk3/emojierapp.vala || die
+	fi
+	if ! use emoji; then
+		touch \
+			tools/main.vala \
+			ui/gtk3/panel.vala || die
+	fi
+	if ! use appindicator; then
+		touch ui/gtk3/panel.vala || die
+	fi
+	if [[ -n ${GENTOO_VER} ]]; then
+		einfo "Try to apply Gentoo specific patch set"
+		eapply "${WORKDIR}"/patches-gentoo/*.patch
+	fi
+
+	# for multiple Python implementations
+	sed -i "s/^\(PYGOBJECT_DIR =\).*/\1/" bindings/Makefile.am || die
+	# fix for parallel install
+	sed -i "/^if ENABLE_PYTHON2/,/^endif/d" bindings/pygobject/Makefile.am || die
+	# require user interaction
+	sed -i "/^TESTS_C += ibus-\(compose\|keypress\)/d" src/tests/Makefile.am || die
+
+	sed -i "/^bash_completion/d" tools/Makefile.am || die
+
+	default
+	eautoreconf
+	xdg_environment_reset
+}
+
+src_configure() {
+	local unicodedir="${EPREFIX}"/usr/share/unicode
+	local python_conf=()
+	if use python; then
+		python_setup
+		python_conf+=(
+			$(use_enable gui setup)
+			--with-python=${EPYTHON}
+		)
+	else
+		python_conf+=( --disable-setup )
+	fi
+
+	if tc-is-cross-compiler && { use emoji || use unicode; }; then
+		mkdir -p "${S}-build"
+		pushd "${S}-build" >/dev/null 2>&1 || die
+		ECONF_SOURCE=${S} econf_build --enable-static \
+			--disable-{dconf,gtk{2,3},python-library,shared,xim} \
+			ISOCODES_{CFLAG,LIB}S=-DSKIP \
+			$(use_enable emoji emoji-dict) \
+			$(use_enable unicode unicode-dict) \
+			$(use_with unicode ucd-dir "${EPREFIX}/usr/share/unicode-data")
+		popd >/dev/null 2>&1 || die
+	fi
+
+	local myconf=(
+		$(use_enable X xim)
+		$(use_enable appindicator)
+		$(use_enable emoji emoji-dict)
+		$(use_with emoji unicode-emoji-dir "${unicodedir}"/emoji)
+		$(use_with emoji emoji-annotation-dir "${unicodedir}"/cldr/common/annotations)
+		$(use_enable gtk2)
+		$(use_enable gtk3)
+		$(use_enable gtk4)
+		$(use_enable gui ui)
+		$(use_enable introspection)
+		$(use_enable libnotify)
+		$(use_enable nls)
+		$(use_enable systemd systemd-services)
+		$(use_enable test tests)
+		$(use_enable unicode unicode-dict)
+		$(use_with unicode ucd-dir "${EPREFIX}/usr/share/unicode-data")
+		$(use_enable vala)
+		$(use_enable wayland)
+		"${python_conf[@]}"
+	)
+	econf "${myconf[@]}"
+}
+
+src_compile() {
+	if tc-is-cross-compiler && { use emoji || use unicode; }; then
+		emake -C "${S}-build/src" \
+			$(usex emoji emoji-parser '') \
+			$(usex unicode unicode-parser '')
+		emake -C src \
+			$(usex emoji emoji-parser '') \
+			$(usex unicode unicode-parser '')
+		cp \
+			$(usex emoji "${S}-build/src/emoji-parser" '') \
+			$(usex unicode "${S}-build/src/unicode-parser" '') \
+			src || die
+	fi
+	emake
+}
+
+src_test() {
+	unset DBUS_SESSION_BUS_ADDRESS
+	virtx dbus-run-session emake check
+}
+
+src_install() {
+	default
+	# Remove la files
+	find "${ED}" -name '*.la' -delete || die
+
+	# Remove stray python files generated by the build system
+	find "${ED}" -name '*.pyc' -exec rm -f {} \; || die
+	find "${ED}" -name '*.pyo' -exec rm -f {} \; || die
+
+	if use python; then
+		python_install() {
+			emake -C bindings/pygobject \
+				pyoverridesdir="$(${EPYTHON} -c 'import gi; print(gi._overridesdir)')" \
+				DESTDIR="${D}" \
+				install
+
+			python_optimize
+		}
+		python_foreach_impl python_install
+	fi
+
+	keepdir /usr/share/ibus/engine
+
+	newbashcomp tools/${PN}.bash ${PN}
+
+	insinto /etc/X11/xinit/xinput.d
+	newins xinput-${PN} ${PN}.conf
+}
+
+pkg_postinst() {
+	use gtk2 && gnome2_query_immodules_gtk2
+	use gtk3 && gnome2_query_immodules_gtk3
+	xdg_icon_cache_update
+	gnome2_schemas_update
+	dconf update
+}
+
+pkg_postrm() {
+	use gtk2 && gnome2_query_immodules_gtk2
+	use gtk3 && gnome2_query_immodules_gtk3
+	xdg_icon_cache_update
+	gnome2_schemas_update
+}