app-text/libebook: fix RDEPEND typo

Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 60 insertions, 0 deletions

diff --git a/app-text/libebook/libebook-0.1.3-r2.ebuild b/app-text/libebook/libebook-0.1.3-r2.ebuild
new file mode 100644
index 000000000000..28eae3a3163b
--- /dev/null
+++ b/app-text/libebook/libebook-0.1.3-r2.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_P="libe-book-${PV}"
+inherit autotools flag-o-matic
+
+DESCRIPTION="Library parsing various ebook formats"
+HOMEPAGE="https://sourceforge.net/projects/libebook/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="amd64 ~arm arm64 ~ppc64 x86"
+IUSE="doc test tools"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-text/liblangtag
+	dev-libs/icu:=
+	dev-libs/librevenge
+	dev-libs/libxml2
+	sys-libs/zlib
+"
+DEPEND="${RDEPEND}
+	dev-libs/boost
+	dev-util/gperf
+"
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	test? ( dev-util/cppunit )
+"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=( "${FILESDIR}/${P}-icu-68.patch" )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-static
+		--disable-werror
+		$(use_with doc docs)
+		$(use_enable test tests)
+		$(use_with tools)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -type f -delete || die
+}