app-text/libmwaw: Fix CVE-2017-9433

Also drop unused RDEPEND.

Gentoo-bug: 621880

Package-Manager: Portage-2.3.6, Repoman-2.3.1

1 files changed, 52 insertions, 0 deletions

diff --git a/app-text/libmwaw/libmwaw-0.3.11-r1.ebuild b/app-text/libmwaw/libmwaw-0.3.11-r1.ebuild
new file mode 100644
index 000000000000..8be0198bd0f6
--- /dev/null
+++ b/app-text/libmwaw/libmwaw-0.3.11-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+EGIT_REPO_URI="git://git.code.sf.net/p/libmwaw/libmwaw"
+[[ ${PV} == 9999 ]] && inherit autotools git-r3
+
+DESCRIPTION="Library parsing many pre-OSX MAC text formats"
+HOMEPAGE="https://sourceforge.net/p/libmwaw/wiki/Home/"
+[[ ${PV} == 9999 ]] || SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+
+[[ ${PV} == 9999 ]] || \
+KEYWORDS="~amd64 ~arm ~x86"
+
+IUSE="doc static-libs tools"
+
+RDEPEND="
+	dev-libs/librevenge
+	sys-libs/zlib
+"
+DEPEND="${RDEPEND}
+	sys-devel/libtool
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+
+PATCHES=( "${FILESDIR}/${P}-CVE-2017-9433.patch" )
+
+src_prepare() {
+	default
+	[[ ${PV} == 9999 ]] && eautoreconf
+}
+
+src_configure() {
+	# zip is hard enabled as the zlib is dep on the rdeps anyway
+	econf \
+		--enable-zip \
+		--disable-werror \
+		--with-sharedptr=c++11 \
+		$(use_with doc docs) \
+		$(use_enable static-libs static) \
+		$(use_enable tools)
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}