app-text/evince: Version bump to 43.1

Signed-off-by: Guillermo Joandet <gjoandet@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/27979
Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 126 insertions, 0 deletions

diff --git a/app-text/evince/Manifest b/app-text/evince/Manifest
index 60881c518262..b857c05e0f0d 100644
--- a/app-text/evince/Manifest
+++ b/app-text/evince/Manifest
@@ -1,2 +1,3 @@
 DIST evince-42.3.tar.xz 2856080 BLAKE2B 55711dd1869e9cce783845683093bb621b416de66f1d53f901353f6f66ff97ec80ce45e0d32e346b2b37d18285568d01ee96cfe851b09f893565d277651d837c SHA512 4ec212e90c3fd259a2afe191592c135938766b11c6891297a10dc34152f69bba9350a467c394ec6cacde5bd16ced02d0c38b7a112dd7d676f53b12fd1b29a62e
 DIST evince-43.0.tar.xz 2908508 BLAKE2B 5f1a9a697693a64c2b54ae5d5499ae8993b02f2df0b1706d0335770037285bb13e2af5254d7ff65ae4abb5a0c8ed6e338c61306f47e121de8c6546407c8968d5 SHA512 dd50ba45c4eb56f8af1df38f7a12c3c13747a1053bb97c8600d85cbc398e340d7bc5db73f441b68cfb8294ab985be361e48605cdc5e3dccb051d917869a12ba9
+DIST evince-43.1.tar.xz 2909512 BLAKE2B 1695320814aca28df17e5bbe6f4000b0191b9b600895c529d4ccd5628335fc4dd4fa788ddfe54c06fe37da12705add93f7df99a8c0dfb1060b8fd497aabae596 SHA512 c12d7b6e961a74c8e31b604f232483576289ba9e5a37faa766f4e5aaa95bdcbf37cf98c1d28de45ad1728452b0a2408fe4fe245dc76289a21e7664c96237d09f
diff --git a/app-text/evince/evince-43.1.ebuild b/app-text/evince/evince-43.1.ebuild
new file mode 100644
index 000000000000..ca49f79daed2
--- /dev/null
+++ b/app-text/evince/evince-43.1.ebuild
@@ -0,0 +1,125 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson systemd xdg
+
+DESCRIPTION="Simple document viewer for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Evince"
+
+LICENSE="GPL-2+ CC-BY-SA-3.0"
+# subslot = evd3.(suffix of libevdocument3)-evv3.(suffix of libevview3)
+SLOT="0/evd3.4-evv3.3"
+IUSE="cups djvu dvi gstreamer gnome gnome-keyring gtk-doc +introspection nautilus postscript spell tiff xps"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-solaris"
+
+# atk used in libview
+# bundles unarr
+DEPEND="
+	|| (
+		>=app-accessibility/at-spi2-core-2.46.0
+		dev-libs/atk
+	)
+	>=dev-libs/glib-2.44.0:2
+	>=gui-libs/libhandy-1.5.0:1=
+	>=dev-libs/libxml2-2.5:2
+	sys-libs/zlib:=
+	>=x11-libs/gdk-pixbuf-2.40:2
+	>=x11-libs/gtk+-3.22.0:3[cups?,introspection?]
+	gnome-base/gsettings-desktop-schemas
+	>=x11-libs/cairo-1.10:=
+	>=app-text/poppler-22.02.0[cairo]
+	>=app-arch/libarchive-3.6.0
+	djvu? ( >=app-text/djvu-3.5.22:= )
+	dvi? (
+		>=app-text/libspectre-0.2:=
+		dev-libs/kpathsea:=
+	)
+	gstreamer? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+		media-libs/gst-plugins-good:1.0 )
+	gnome? ( gnome-base/gnome-desktop:3= )
+	gnome-keyring? ( >=app-crypt/libsecret-0.5 )
+	introspection? ( >=dev-libs/gobject-introspection-1:= )
+	nautilus? ( >=gnome-base/nautilus-3.28.0 <gnome-base/nautilus-42.20 )
+	postscript? ( >=app-text/libspectre-0.2:= )
+	spell? ( >=app-text/gspell-1.6.0:= )
+	tiff? ( >=media-libs/tiff-4.0:0= )
+	xps? ( >=app-text/libgxps-0.2.1:= )
+"
+RDEPEND="${DEPEND}
+	gnome-base/gvfs
+	gnome-base/librsvg
+	|| (
+		>=x11-themes/adwaita-icon-theme-2.17.1
+		>=x11-themes/hicolor-icon-theme-0.10
+	)
+"
+BDEPEND="
+	gtk-doc? (
+		>=dev-util/gi-docgen-2021.1
+		app-text/docbook-xml-dtd:4.3
+	)
+	dev-libs/appstream-glib
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	xdg_environment_reset
+
+	# Do not depend on adwaita-icon-theme, bug #326855, #391859
+	# https://gitlab.freedesktop.org/xdg/default-icon-theme/issues/7
+	sed -i '/adwaita_icon_theme_dep/d' meson.build shell/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Ddevelopment=false
+		-Dplatform=gnome
+
+		-Dviewer=true
+		-Dpreviewer=true
+		-Dthumbnailer=true
+		$(meson_use nautilus)
+
+		-Dcomics=enabled
+		$(meson_feature djvu)
+		$(meson_feature dvi)
+		-Dpdf=enabled
+		$(meson_feature postscript ps)
+		$(meson_feature tiff)
+		$(meson_feature xps)
+
+		$(meson_use gtk-doc gtk_doc)
+		-Duser_doc=true
+		$(meson_use introspection)
+		-Ddbus=true
+		$(meson_feature gnome-keyring keyring)
+		$(meson_feature cups gtk_unix_print)
+		$(meson_feature gnome thumbnail_cache)
+		$(meson_feature gstreamer multimedia)
+		$(meson_feature spell gspell)
+
+		-Dinternal_synctex=true
+
+		-Dsystemduserunitdir="$(systemd_get_userunitdir)"
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}