app-text/recode: add 3.7.13

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 70 insertions, 0 deletions

diff --git a/app-text/recode/Manifest b/app-text/recode/Manifest
index 0f94ebaf0544..81c6c925cb95 100644
--- a/app-text/recode/Manifest
+++ b/app-text/recode/Manifest
@@ -1 +1,2 @@
 DIST recode-3.7.12.tar.gz 2399126 BLAKE2B 420ba6f96d532da4ae0e1861b512c39ad59f1f63b0e0ef061dcff95c15ff4ed82a3b7bb72f6abb29f85588476a76cb5d50151ca9e3f857c2c1c09727ccdd2890 SHA512 365602bf7b20e5362d13d1ab5269419f7f0838fb81dc01c466ea99c38eb1b979f8d707d24ca3dabbd3a0c65cde97704b570007ac60689d88bbafd33351d37d95
+DIST recode-3.7.13.tar.gz 2400432 BLAKE2B 457ba7855aeb5ae8b0cc32ee82b5b61b1b46ba2908406c0c10a76ae242343f421e81038b9bb6784089e8e3e687ecc0f61a6263c24f6b234962f94853e9359734 SHA512 af86754ed2ed1dc414f1dd7ab3564d606abb309766fb02bf085e56241527a74ac7141617956d01b0797e8e426cfb39ec597bd221d8ad58d9246e96b228e65b00
diff --git a/app-text/recode/recode-3.7.13.ebuild b/app-text/recode/recode-3.7.13.ebuild
new file mode 100644
index 000000000000..b028f8eba188
--- /dev/null
+++ b/app-text/recode/recode-3.7.13.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit autotools flag-o-matic python-any-r1 toolchain-funcs
+
+DESCRIPTION="Convert files between various character sets"
+HOMEPAGE="https://github.com/rrthomas/recode"
+SRC_URI="https://github.com/rrthomas/recode/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+# librecode soname version
+SLOT="0/3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~x86-solaris"
+IUSE="nls test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="virtual/libiconv"
+DEPEND="
+	${RDEPEND}
+	sys-devel/flex
+"
+BDEPEND="
+	nls? ( sys-devel/gettext )
+	test? (
+		${PYTHON_DEPS}
+		$(python_gen_any_dep '
+			dev-python/cython[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+python_check_deps() {
+	python_has_version "dev-python/cython[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	tc-export CC LD
+
+	# on solaris -lintl is needed to compile
+	[[ ${CHOST} == *-solaris* ]] && append-libs "-lintl"
+
+	# -fanalyzer substantially slows down the build and isn't useful for
+	# us. It's useful for upstream as it's static analysis, but it's not
+	# useful when just getting something built.
+	export gl_cv_warn_c__fanalyzer=no
+
+	econf \
+		$(use_enable nls) \
+		--disable-static
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name '*.la' -delete || die
+}