dev-games/tiled: version bump 1.2.4

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Michael Palimaka <kensington@gentoo.org>

2 files changed, 63 insertions, 0 deletions

diff --git a/dev-games/tiled/Manifest b/dev-games/tiled/Manifest
index a2347038357d..3a9abedf1db8 100644
--- a/dev-games/tiled/Manifest
+++ b/dev-games/tiled/Manifest
@@ -1 +1,2 @@
 DIST tiled-1.2.3.tar.gz 16848125 BLAKE2B cc2ab2a2ab14a575da1f47a415e1c544de9a80417ea5a081684893bad253fc742f89f5e17739bfe0617f859f6921ab214c2e8bdefe321545008b277684e654b1 SHA512 0c9e818872b1e8de67ff8d943dc47abb63667bc45917b29dca959b0a32594be4ffb156469375c0f5c4a4fa71ee85b05c018c58a2f581a860405cbb12c9c0aac5
+DIST tiled-1.2.4.tar.gz 16875074 BLAKE2B 19d9e000949a889af90f48c31862aab8d00cbd968d518bc48e58775763ff2b293d5e82f10b8ec45dda936bf81b177f88aa4962900c7b70b01ce514fabf717c46 SHA512 a16fcb3fcceb11397cc981f10a558215264cf2c340639fbc001d384cfd9bc138c05ed40894a03d103af8a7d629c0be9fa6d5a4058fd9c563806920efef8e2cb7
diff --git a/dev-games/tiled/tiled-1.2.4.ebuild b/dev-games/tiled/tiled-1.2.4.ebuild
new file mode 100644
index 000000000000..56763ea7c4f4
--- /dev/null
+++ b/dev-games/tiled/tiled-1.2.4.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_6 )
+inherit gnome2-utils multilib python-single-r1 qmake-utils xdg-utils
+
+DESCRIPTION="A general purpose tile map editor"
+HOMEPAGE="https://www.mapeditor.org/"
+SRC_URI="https://github.com/bjorn/tiled/archive/v${PV}/${P}.tar.gz"
+
+LICENSE="BSD BSD-2 GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="examples python"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	>=dev-qt/qtcore-5.9:5
+	>=dev-qt/qtgui-5.9:5
+	>=dev-qt/qtnetwork-5.9:5
+	>=dev-qt/qtwidgets-5.9:5
+	sys-libs/zlib
+	python? ( ${PYTHON_DEPS} )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="dev-qt/linguist-tools:5"
+
+DOCS=( AUTHORS COPYING NEWS.md README.md )
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	eqmake5 LIBDIR="/usr/$(get_libdir)" PREFIX="/usr" DISABLE_PYTHON_PLUGIN="$(usex !python)"
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+
+	einstalldocs
+
+	if use examples ; then
+		docompress -x /usr/share/doc/${PF}/examples
+		dodoc -r examples
+	fi
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}