dev-lang/swi-prolog: bump development version

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Keri Harris <keri@gentoo.org>

2 files changed, 104 insertions, 0 deletions

diff --git a/dev-lang/swi-prolog/Manifest b/dev-lang/swi-prolog/Manifest
index 5a1e8dfd7383..1cfe6dfac736 100644
--- a/dev-lang/swi-prolog/Manifest
+++ b/dev-lang/swi-prolog/Manifest
@@ -1,3 +1,4 @@
 DIST swipl-8.0.3.tar.gz 10418553 BLAKE2B d7d381a3070384164f9788060e1c431cc4658dd3e2144fc4c186c9f5395fb7356593766dcaff3ff424f19f917c8a4b56da31b019bd2206a7f794ece549043b76 SHA512 e3a0788befb5499be6f70524ef398dc3282a38891f20519dd23ec92f216fc1919a76656e4b648c3dc9d94e578dc2663439ff976eb52ca0dba5a6594f8d4d3037
 DIST swipl-8.1.29.tar.gz 10902999 BLAKE2B 2163cbe4ce772fc0ba8dc961aabf5d3940e0b735bb4688050041d8bcbe6c052d5308696cbbcec49ecc100db44faa960fd8520d89a934f9b05994170c5fab5bff SHA512 0aeaa093a0cc39375b25f2ac642dec99c50aad82c5fa0069be6c5c7bf3ba53deb20e4c887e47649874305e91e7c963bab2515ab8a48db6cdfae6e4560aee063f
 DIST swipl-8.1.30.tar.gz 10921576 BLAKE2B ce163c7600554e5a2f62a75c4fc17444c115adda96527068f6ee707f390c9383e8e2f7a24cf493903edd895fd5ece186b7645cad50d44805d57617c7182ba120 SHA512 1b8be8d4f987bb4ce4e3ea82ab02c0e89f2fba68818a15bf2b86593ba53724005cf617f69e41a4394009dcd0abda84103cba4d4bb3ae562b29d942d0f55cad9a
+DIST swipl-8.1.31.tar.gz 10949562 BLAKE2B 60a4dd1da1cce309f45e557b25d7fa384ac0d75bf819b5e49d8303cae260d6576b01adb9c26bd7496962ae64a3b012c146408f8adaf6a253c526d50f5ed6b74c SHA512 629dd038fac868b0a2bcf71807ff6e795fd9c83a21358ef679b27bde8197b6f0aaf588a033720db9b1dd88c27dfeb0a42a13bc04e938f504524b48fa34891f1d
diff --git a/dev-lang/swi-prolog/swi-prolog-8.1.31.ebuild b/dev-lang/swi-prolog/swi-prolog-8.1.31.ebuild
new file mode 100644
index 000000000000..2293c183ae1c
--- /dev/null
+++ b/dev-lang/swi-prolog/swi-prolog-8.1.31.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils eutils flag-o-matic multilib
+
+PATCHSET_VER="0"
+
+DESCRIPTION="versatile implementation of the Prolog programming language"
+HOMEPAGE="http://www.swi-prolog.org/"
+SRC_URI="http://www.swi-prolog.org/download/devel/src/swipl-${PV}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+IUSE="archive berkdb debug doc +gmp java +libedit libressl minimal odbc pcre qt5 readline ssl test uuid X yaml"
+RESTRICT="!test? ( test )"
+
+RDEPEND="sys-libs/ncurses:=
+	sys-libs/zlib
+	archive? ( app-arch/libarchive )
+	berkdb? ( >=sys-libs/db-4:= )
+	odbc? ( dev-db/unixODBC )
+	pcre? ( dev-libs/libpcre )
+	readline? ( sys-libs/readline:= )
+	libedit? ( dev-libs/libedit )
+	gmp? ( dev-libs/gmp:0 )
+	ssl? (
+		!libressl? ( dev-libs/openssl:0 )
+		libressl? ( dev-libs/libressl )
+	)
+	java? ( >=virtual/jdk-1.7:= )
+	uuid? ( dev-libs/ossp-uuid )
+	qt5? (
+		dev-qt/qtwidgets:5
+		dev-qt/qtgui:5
+	)
+	X? (
+		virtual/jpeg:0
+		x11-libs/libX11
+		x11-libs/libXft
+		x11-libs/libXinerama
+		x11-libs/libXpm
+		x11-libs/libXt
+		x11-libs/libICE
+		x11-libs/libSM )
+	yaml? ( dev-libs/libyaml )"
+
+DEPEND="${RDEPEND}
+	X? ( x11-base/xorg-proto )
+	java? ( test? ( =dev-java/junit-3.8* ) )"
+
+S="${WORKDIR}/swipl-${PV}"
+BUILD_DIR="${S}/build"
+CMAKE_USE_DIR="${S}"
+
+src_prepare() {
+	if [[ -d "${WORKDIR}"/${PV} ]] ; then
+		eapply "${WORKDIR}"/${PV}
+	fi
+	eapply_user
+
+	sed -i -e "s|\(SWIPL_INSTALL_PREFIX\)   lib/.*)|\1   $(get_libdir)/swipl)|" CMakeLists.txt || die
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	append-flags -fno-strict-aliasing
+	use debug && append-flags -DO_DEBUG
+
+	mycmakeargs=(
+		-DSWIPL_INSTALL_PREFIX=$(get_libdir)/swipl
+		-DUSE_GMP=$(usex gmp)
+		-DINSTALL_DOCUMENTATION=$(use doc && usex archive)
+		-DSWIPL_PACKAGES_BASIC=$(usex !minimal)
+		-DSWIPL_PACKAGES_ARCHIVE=$(usex archive)
+		-DSWIPL_PACKAGES_ODBC=$(usex odbc)
+		-DSWIPL_PACKAGES_BDB=$(usex berkdb)
+		-DSWIPL_PACKAGES_PCRE=$(usex pcre)
+		-DSWIPL_PACKAGES_YAML=$(usex yaml)
+		-DSWIPL_PACKAGES_SSL=$(usex ssl)
+		-DSWIPL_PACKAGES_JAVA=$(usex java)
+		-DSWIPL_PACKAGES_QT=$(usex qt5)
+		-DSWIPL_PACKAGES_X=$(usex X)
+		-DSWIPL_PACKAGES_TERM=$(if use libedit || use readline; then echo yes; else echo no; fi)
+		)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	XDG_CONFIG_DIRS="${HOME}" \
+	XDG_DATA_DIRS="${HOME}" \
+		cmake-utils_src_compile
+}
+
+src_test() {
+	USE_PUBLIC_NETWORK_TESTS=false \
+	USE_ODBC_TESTS=false \
+		cmake-utils_src_test -V
+}