dev-libs/amdgpu-pro-opencl: bump to 17.40.492261

Suggested-by: Vladyslav Brovko <brovushkin+gentoo@gmail.com>
Gentoo-Bug: 635236
Closes: 6207
Package-Manager: Portage-2.3.13, Repoman-2.3.3

2 files changed, 82 insertions, 0 deletions

diff --git a/dev-libs/amdgpu-pro-opencl/Manifest b/dev-libs/amdgpu-pro-opencl/Manifest
index 8f837f298666..ee860d521420 100644
--- a/dev-libs/amdgpu-pro-opencl/Manifest
+++ b/dev-libs/amdgpu-pro-opencl/Manifest
@@ -1,3 +1,4 @@
 DIST amdgpu-pro-17.10-429170.tar.xz 121382128 SHA256 cb1ea7f9756f197a976138d2c00f239ae4ee43b839fbb1ea57f8770957d4afd6 SHA512 2d9d0a97478564e259dc8494083df8dc13e3bc664384978aff369070b1105703653d8dc4dca38e94dc8bdf3ddfb5c6f4de39cec5a9b263423de8fb91fd0117c6 WHIRLPOOL 1e07579d2c9d5d8a796973658cbb6627418b133a630ca5e977f93da0d27b900da2078d2ea8b35a13071b0b05e3d5e7f47e17d61042dcca60709f6599c18380a2
 DIST amdgpu-pro-17.30-458935.tar.xz 393634984 SHA256 3652a5c9476a650a3e3cd89bcd7ac119ed7d16a570501eeeea6a902cbc6f9488 SHA512 3f517ce13e102edb820f8f9538e0894c794d767816f99774fbfec342adb6912712664f069db2542412baabb24ee198204f38757407c29aff238ed1772dc3caab WHIRLPOOL 29a5b06657767255ace0529467ca56a904a021254f7dab854b1fd3ac843108ac346d3c4e97e10ef53844152de116581bff7c3aa8f4f066a08becb88e59918da3
 DIST amdgpu-pro-17.30-465504.tar.xz 394216628 SHA256 b74494d142542164b5582e8bed845315f788aa3d9eb0c1ed5f2a6c5f982beaf5 SHA512 fa515d5397488ebd4271988f7b9b538190c4277a3c4dcaeb4b05f5cd5bdec657f13546de644b1a6825c88bd3b73e6c1a6aaa6b6c74e3cf942783b2df530cf4c7 WHIRLPOOL 3a1617cd8b8fd096614cf04b7e716b607ec718d122b286533d8dabc862c82b644ba864eb661b1d5e5da45c8fe674192d3f8038dbd85311d9ffc5c6f793f7d32b
+DIST amdgpu-pro-17.40-492261.tar.xz 361491288 SHA256 b0645157577c9ff175dc02487c4c682ded2624c8c2cfd6aa603960962e1d07b0 SHA512 b10d67f4fc7bfbf8f1de46e5202fabc3443e969759817d497449d911d4c591256cfdf73372013fdc67bd89c44ffe389c021c9f77ba27f55cbb5257af550bd148 WHIRLPOOL 61af42850786eb585442692437327e8a1baeb0dc905b6d84586f0a58e77e36e76c754334e5da3bbd25d813a73a9cd1303885a1267821a53bb6bb99b780108503
diff --git a/dev-libs/amdgpu-pro-opencl/amdgpu-pro-opencl-17.40.492261.ebuild b/dev-libs/amdgpu-pro-opencl/amdgpu-pro-opencl-17.40.492261.ebuild
new file mode 100644
index 000000000000..a7815bc7842e
--- /dev/null
+++ b/dev-libs/amdgpu-pro-opencl/amdgpu-pro-opencl-17.40.492261.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit unpacker versionator
+
+SUPER_PN='amdgpu-pro'
+MY_PV=$(replace_version_separator 2 '-')
+
+DESCRIPTION="Proprietary OpenCL implementation for AMD GPUs"
+HOMEPAGE="https://support.amd.com/en-us/kb-articles/Pages/AMDGPU-PRO-Driver-for-Linux-Release-Notes.aspx"
+SRC_URI="${SUPER_PN}-${MY_PV}.tar.xz"
+
+LICENSE="AMD-GPU-PRO-EULA"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RESTRICT="mirror fetch strip"
+
+DEPEND="dev-util/patchelf"
+RDEPEND="dev-libs/ocl-icd"
+
+QA_PREBUILT="/opt/${SUPER_PN}/lib*/*"
+
+S="${WORKDIR}/${SUPER_PN}-${MY_PV}"
+
+pkg_nofetch() {
+	local pkgver=$(get_version_component_range 1-2)
+	einfo "Please download the AMDGPU-Pro Driver ${pkgver} for Ubuntu from"
+	einfo "    ${HOMEPAGE}"
+	einfo "The archive should then be placed into ${DISTDIR}."
+}
+
+src_unpack() {
+	default
+
+	local ids_ver="1.0.0"
+	local libdrm_ver="2.4.82"
+	local patchlevel=$(get_version_component_range 3)
+	cd "${S}" || die
+	unpack_deb opencl-${SUPER_PN}-icd_${MY_PV}_amd64.deb
+	unpack_deb libdrm-${SUPER_PN}-amdgpu1_${libdrm_ver}-${patchlevel}_amd64.deb
+	unpack_deb ids-${SUPER_PN}_${ids_ver}-${patchlevel}_all.deb
+}
+
+src_prepare() {
+	default
+
+	cd "${S}/opt/${SUPER_PN}/lib/x86_64-linux-gnu" || die
+	patchelf --set-rpath '$ORIGIN' libamdocl64.so || die "Failed to fix library rpath"
+}
+
+src_install() {
+
+	into "/opt/${SUPER_PN}"
+	dolib opt/${SUPER_PN}/lib/x86_64-linux-gnu/*
+	insinto "/opt/${SUPER_PN}"
+	doins -r opt/${SUPER_PN}/share
+
+	insinto /etc/OpenCL/vendors/
+	echo "/opt/${SUPER_PN}/$(get_libdir)/libamdocl64.so" > "${SUPER_PN}.icd" || die "Failed to generate ICD file"
+	doins "${SUPER_PN}.icd"
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		ewarn "Please note that using proprietary OpenCL libraries together with the"
+		ewarn "Open Source amdgpu stack is not officially supported by AMD. Do not ask them"
+		ewarn "for support in case of problems with this package."
+		ewarn ""
+		ewarn "Furthermore, if you have the whole AMDGPU-Pro stack installed this package"
+		ewarn "will almost certainly conflict with it. This might change once AMDGPU-Pro"
+		ewarn "has become officially supported by Gentoo."
+	fi
+
+	elog "AMD OpenCL driver relies on dev-libs/ocl-icd to work. To enable it, please run"
+	elog ""
+	elog "    eselect opencl set ocl-icd"
+	elog ""
+}