dev-libs/appstream: 0.14.4 version bump

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 78 insertions, 0 deletions

diff --git a/dev-libs/appstream/Manifest b/dev-libs/appstream/Manifest
index 8bb471ce7ea7..0d4d2a947cb1 100644
--- a/dev-libs/appstream/Manifest
+++ b/dev-libs/appstream/Manifest
@@ -1 +1,2 @@
 DIST AppStream-0.14.3.tar.xz 2277536 BLAKE2B 99ceae6873c189b289143c8ab59eaacfbadbbe7cf05db96079c00ba09c82aeac63f4436e1b9e54b8d172aa7e9f609583cf2a78d3f44ce880cb1a326034432563 SHA512 b4c41b44375091636cc46e2f7f5e0b86612474faa6d55010caee78cb9c9ac468d093cf261184d900be7aae8513dc72d2821ff9ee17786e123c86a928ce5e9135
+DIST AppStream-0.14.4.tar.xz 2309444 BLAKE2B 0c1fd20a01d0fe59d1b1ff029e4fbddbf9cea833d4665549480744e48dc0b3615b0d507278c75025c99ccda21b97e25e62496ecfc49dbe6527132f5dad5d6ad5 SHA512 86bd98e94f3e730d37030be31c6ea0000ba12b35e13778458c0f50bad75babf8c8e93b62492a2546a42f750f91ae81f3456d04e63ad9a4acb804cf38493440a4
diff --git a/dev-libs/appstream/appstream-0.14.4.ebuild b/dev-libs/appstream/appstream-0.14.4.ebuild
new file mode 100644
index 000000000000..ff3c834181fa
--- /dev/null
+++ b/dev-libs/appstream/appstream-0.14.4.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson xdg-utils
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/ximion/${PN}"
+else
+	SRC_URI="https://www.freedesktop.org/software/appstream/releases/AppStream-${PV}.tar.xz"
+	S="${WORKDIR}/AppStream-${PV}"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+fi
+
+DESCRIPTION="Cross-distro effort for providing metadata for software in the Linux ecosystem"
+HOMEPAGE="https://www.freedesktop.org/wiki/Distributions/AppStream/"
+
+LICENSE="LGPL-2.1+ GPL-2+"
+# check as_api_level
+SLOT="0/4"
+IUSE="apt doc +introspection qt5 test"
+RESTRICT="test" # bug 691962
+
+RDEPEND="
+	dev-db/lmdb:=
+	>=dev-libs/glib-2.58:2
+	dev-libs/libxml2:2
+	dev-libs/libyaml
+	dev-libs/snowball-stemmer
+	net-misc/curl
+	introspection? ( >=dev-libs/gobject-introspection-1.56:= )
+	qt5? ( dev-qt/qtcore:5 )
+"
+DEPEND="${RDEPEND}
+	test? ( qt5? ( dev-qt/qttest:5 ) )
+"
+BDEPEND="
+	dev-libs/appstream-glib
+	dev-libs/libxslt
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	doc? ( app-text/docbook-xml-dtd:4.5 )
+	test? ( dev-qt/linguist-tools:5 )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.14.3-disable-Werror-flags.patch # bug 733774
+)
+
+src_prepare() {
+	default
+	sed -e "/^as_doc_target_dir/s/appstream/${PF}/" -i docs/meson.build || die
+	if ! use test; then
+		sed -e "/^subdir.*tests/s/^/#DONT /" -i {,qt/}meson.build || die # bug 675944
+	fi
+}
+
+src_configure() {
+	xdg_environment_reset
+
+	local emesonargs=(
+		-Dapidocs=false
+		-Ddocs=false
+		-Dcompose=false
+		-Dmaintainer=false
+		-Dstemming=true
+		-Dvapi=false
+		-Dapt-support=$(usex apt true false)
+		-Dinstall-docs=$(usex doc true false)
+		-Dgir=$(usex introspection true false)
+		-Dqt=$(usex qt5 true false)
+	)
+
+	meson_src_configure
+}