dev-libs/grantlee: 0.5.2 version bump

Package-Manager: Portage-2.3.82, Repoman-2.3.20
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 60 insertions, 0 deletions

diff --git a/dev-libs/grantlee/grantlee-5.2.0.ebuild b/dev-libs/grantlee/grantlee-5.2.0.ebuild
new file mode 100644
index 000000000000..9d5b5a2b9586
--- /dev/null
+++ b/dev-libs/grantlee/grantlee-5.2.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+VIRTUALX_REQUIRED="test"
+inherit cmake-utils virtualx
+
+DESCRIPTION="C++ string template engine based on the Django template system"
+HOMEPAGE="https://github.com/steveire/grantlee"
+SRC_URI="http://downloads.grantlee.org/${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="debug doc test"
+
+BDEPEND="
+	doc? ( app-doc/doxygen[dot] )
+	test? ( dev-qt/linguist-tools:5 )
+"
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtgui:5
+"
+DEPEND="${RDEPEND}
+	test? ( dev-qt/qttest:5 )
+"
+
+RESTRICT+=" !test? ( test )"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.3.0-nonfatal-warnings.patch"
+	"${FILESDIR}/${P}-slot.patch"
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTS=$(usex test)
+	)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+
+	use doc && cmake-utils_src_compile docs
+}
+
+src_test() {
+	virtx cmake-utils_src_test
+}
+
+src_install() {
+	use doc && local HTML_DOCS=("${BUILD_DIR}/apidox/")
+
+	cmake-utils_src_install
+}