dev-libs/libinput: Version bump to 1.26.0

Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 103 insertions, 0 deletions

diff --git a/dev-libs/libinput/Manifest b/dev-libs/libinput/Manifest
index 93761637c86b..1d92acd914f1 100644
--- a/dev-libs/libinput/Manifest
+++ b/dev-libs/libinput/Manifest
@@ -1 +1,2 @@
 DIST libinput-1.25.0.tar.bz2 812020 BLAKE2B 03034b6315c281d7eee6a7bc1f4c799c2c7f74add7a195501de75feb6b98fa8dc601b7573da5586b2b2882c3cfaddfad62f5c1b836402dce1f463bdb2884945d SHA512 b9dc3f3b5f34c82399dfb7ccb5f65d19a596c415f0198b39e3f360f5b87c42124a5355c8d9f6f42cc9ae2d4f9a90fe5da6260136fa83d278048392f93381a84b
+DIST libinput-1.26.0.tar.bz2 821648 BLAKE2B 50df13597f5bba9cf6ff283bc6fe63ad28d76137c2ec4d1aee7c8a5342ca319f222e8dd486a4b943f9c6e42c79896d229cd1f64f1667b87478666f631516a49b SHA512 7cd6a46ff6f43eab4cc7558b77804005aa94d75b9b07b8d954c57b8521b2dfb182018043bebaf5f3ab7ec8b56fc7313cbd193b4670c065ccc51c719d518b7c98
diff --git a/dev-libs/libinput/libinput-1.26.0.ebuild b/dev-libs/libinput/libinput-1.26.0.ebuild
new file mode 100644
index 000000000000..bb8f414e33ec
--- /dev/null
+++ b/dev-libs/libinput/libinput-1.26.0.ebuild
@@ -0,0 +1,102 @@
+# Copyright 2014-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+inherit meson optfeature python-any-r1 udev
+
+DESCRIPTION="Library to handle input devices in Wayland"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/libinput/ https://gitlab.freedesktop.org/libinput/libinput"
+SRC_URI="https://gitlab.freedesktop.org/${PN}/${PN}/-/archive/${PV}/${P}.tar.bz2"
+
+LICENSE="MIT"
+SLOT="0/10"
+if [[ $(ver_cut 3) -lt 900 ]] ; then
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+IUSE="doc input_devices_wacom test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	input_devices_wacom? ( >=dev-libs/libwacom-0.27:= )
+	>=dev-libs/libevdev-1.9.902
+	>=sys-libs/mtdev-1.1
+	virtual/libudev:=
+	virtual/udev
+"
+DEPEND="
+	${RDEPEND}
+	test? ( >=dev-libs/check-0.9.10 )
+"
+BDEPEND="
+	virtual/pkgconfig
+	doc? (
+		$(python_gen_any_dep '
+			dev-python/commonmark[${PYTHON_USEDEP}]
+			dev-python/recommonmark[${PYTHON_USEDEP}]
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			>=dev-python/sphinx-rtd-theme-0.2.4[${PYTHON_USEDEP}]
+		')
+		>=app-text/doxygen-1.8.3
+		>=media-gfx/graphviz-2.38.0
+	)
+	test? (
+		$(python_gen_any_dep '
+			dev-python/pytest[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		')
+	)
+"
+#	test? ( dev-debug/valgrind )
+
+python_check_deps() {
+	if use doc; then
+		python_has_version \
+			"dev-python/commonmark[${PYTHON_USEDEP}]" \
+			"dev-python/recommonmark[${PYTHON_USEDEP}]" \
+			"dev-python/sphinx[${PYTHON_USEDEP}]" \
+			">=dev-python/sphinx-rtd-theme-0.2.4[${PYTHON_USEDEP}]" \
+		|| return
+	fi
+	if use test; then
+		python_has_version \
+			"dev-python/pytest[${PYTHON_USEDEP}]" \
+			"dev-python/pytest-xdist[${PYTHON_USEDEP}]" \
+		|| return
+	fi
+}
+
+src_prepare() {
+	default
+	sed "s@, '-Werror'@@" -i meson.build || die #744250
+}
+
+src_configure() {
+	# gui can be built but will not be installed
+	local emesonargs=(
+		-Ddebug-gui=false
+		$(meson_use doc documentation)
+		$(meson_use input_devices_wacom libwacom)
+		$(meson_use test tests)
+		-Dudev-dir="${EPREFIX}$(get_udevdir)"
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	if use doc ; then
+		docinto html
+		dodoc -r "${BUILD_DIR}"/Documentation/.
+	fi
+}
+
+pkg_postinst() {
+	optfeature "measure and replay tools" dev-python/libevdev
+	udev_reload
+}
+
+pkg_postrm() {
+	udev_reload
+}