dev-libs/xmlsec: version bump

Closes: https://bugs.gentoo.org/show_bug.cgi?id=658594
Package-Manager: Portage-2.3.40, Repoman-2.3.9

2 files changed, 66 insertions, 0 deletions

diff --git a/dev-libs/xmlsec/Manifest b/dev-libs/xmlsec/Manifest
index 072e9c5ce724..5bb3a245541b 100644
--- a/dev-libs/xmlsec/Manifest
+++ b/dev-libs/xmlsec/Manifest
@@ -1 +1,2 @@
 DIST xmlsec1-1.2.25.tar.gz 1839160 BLAKE2B af480affa84c47c5656889c8114f147e1d9a5ad0f9a494c8913fd180aa5e2cba4773451c4a5f41781026e7617cccf329057182fc3fc3f2bd4e6f007cbe8ac190 SHA512 ac61547a1cbf9016d7f75be3dc5249d6bc8a526bc51715e53ede13f056c1c72c57433a6be200c886000a25826c3e473954ded3ae988f25d37ac4ef4d777c66a6
+DIST xmlsec1-1.2.26.tar.gz 1922183 BLAKE2B 8cb8557a7d24df756655a7dfa45091445adc89cb67169a7620d9d1116f3fb3d982ea45199a53475e29300478c07e8e1168cec79cf9c3b5ff1dd6c840123b982b SHA512 1e3dc3c8c192eefee7b055787bef52ce3bcfafa786224f68af065aa45f4d7da93232da973359b3135615c5981ad4df7c124047d3934e552ab78439472685a7a4
diff --git a/dev-libs/xmlsec/xmlsec-1.2.26.ebuild b/dev-libs/xmlsec/xmlsec-1.2.26.ebuild
new file mode 100644
index 000000000000..70e0604bb856
--- /dev/null
+++ b/dev-libs/xmlsec/xmlsec-1.2.26.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools ltprune
+
+DESCRIPTION="Command line tool for signing, verifying, encrypting and decrypting XML"
+HOMEPAGE="https://www.aleksey.com/xmlsec"
+SRC_URI="https://www.aleksey.com/xmlsec/download/${PN}1-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc gcrypt gnutls libressl nss +openssl static-libs"
+REQUIRED_USE="|| ( gcrypt gnutls nss openssl )
+	gnutls? ( gcrypt )"
+
+RDEPEND=">=dev-libs/libxml2-2.7.4
+	>=dev-libs/libxslt-1.0.20
+	gcrypt? ( >=dev-libs/libgcrypt-1.4.0:0 )
+	gnutls? ( >=net-libs/gnutls-2.8.0 )
+	nss? (
+		>=dev-libs/nspr-4.4.1
+		>=dev-libs/nss-3.9
+	)
+	openssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:0= )
+	)"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+S="${WORKDIR}/${PN}1-${PV}"
+
+src_prepare() {
+	default
+	# conditionally install extra documentation
+	if ! use doc ; then
+		sed -i '/^SUBDIRS/s/docs//' Makefile.am || die
+		eautoreconf
+	fi
+}
+
+src_configure() {
+	econf \
+		--enable-pkgconfig \
+		--with-html-dir=/usr/share/doc/${PF}/html \
+		$(use_enable static-libs static) \
+		$(use_with gcrypt gcrypt "") \
+		$(use_with gnutls gnutls "") \
+		$(use_with nss nspr "") \
+		$(use_with nss nss "") \
+		$(use_with openssl openssl "") \
+		$(use_enable openssl aes)
+}
+
+src_test() {
+	emake TMPFOLDER="${T}" check
+}
+
+src_install() {
+	default
+	prune_libtool_files --all
+}