dev-perl/Authen-Libwrap: -r bump fix for bug #737212

This overrides the magic detection in Build.PL, which was previously
creating problems for LD=lld due to the inclusion of "/usr/lib/" instead
of "/usr/lib64/".

This employs get_libdir to resolve the right version, and passes
expected config into Build.PL, and patches Build.PL to simply die when
the passed values don't look usable, instead of doing some weird config
discovery which could possibly do wrong things.

Bug: https://bugs.gentoo.org/737212
Package-Manager: Portage-2.3.103, Repoman-2.3.22
Signed-off-by: Kent Fredric <kentnl@gentoo.org>

1 files changed, 46 insertions, 0 deletions

diff --git a/dev-perl/Authen-Libwrap/Authen-Libwrap-0.230.0-r2.ebuild b/dev-perl/Authen-Libwrap/Authen-Libwrap-0.230.0-r2.ebuild
new file mode 100644
index 000000000000..79aaf42ae9be
--- /dev/null
+++ b/dev-perl/Authen-Libwrap/Authen-Libwrap-0.230.0-r2.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DIST_AUTHOR=DMUEY
+DIST_VERSION=0.23
+DIST_EXAMPLES=("example.pl")
+inherit perl-module multilib
+
+DESCRIPTION="A Perl access to the TCP Wrappers interface"
+
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="sys-apps/tcp-wrappers"
+DEPEND="dev-perl/Module-Build"
+BDEPEND="${RDEPEND}
+	>=dev-perl/Module-Build-0.420.0
+	virtual/perl-ExtUtils-CBuilder
+	test? (
+		virtual/perl-Test-Simple
+		dev-perl/Test-Exception
+	)
+"
+PATCHES=(
+	"${FILESDIR}/${PN}-0.23-inc-paths.patch"
+)
+PERL_RM_FILES=(
+	t/03_pod.t
+	t/02_maintainer.t
+)
+src_configure() {
+	unset LD
+	if [[ -n "${CCLD}" ]]; then
+		export LD="${CCLD}"
+	fi
+	GENTOO_INCDIR="${EPREFIX}/usr/include" \
+		GENTOO_LIBDIR="${EPREFIX}/usr/$(get_libdir)" \
+		perl-module_src_configure
+}
+src_compile() {
+	./Build --config optimize="${CFLAGS}" build || die
+}