dev-python/aiohttp: add 1.3.5 for net-misc/gns3-server dependency

Closes: https://github.com/gentoo/gentoo/pull/5007

1 files changed, 59 insertions, 0 deletions

diff --git a/dev-python/aiohttp/aiohttp-1.3.5.ebuild b/dev-python/aiohttp/aiohttp-1.3.5.ebuild
new file mode 100644
index 000000000000..739051416f14
--- /dev/null
+++ b/dev-python/aiohttp/aiohttp-1.3.5.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+PYTHON_COMPAT=( python3_{4,5,6} )
+
+inherit distutils-r1 vcs-snapshot
+
+DESCRIPTION="http client/server for asyncio"
+HOMEPAGE="https://pypi.python.org/pypi/aiohttp"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz -> ${P}.tar.gz"
+EGIT_REPO_URI="https://github.com/aio-libs/aiohttp"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+CDEPEND="
+	dev-python/async_timeout[${PYTHON_USEDEP}]
+	dev-python/chardet[${PYTHON_USEDEP}]
+	>=dev-python/multidict-2.1.4[${PYTHON_USEDEP}]
+	>=dev-python/yarl-0.9.8[${PYTHON_USEDEP}]
+	<dev-python/yarl-0.10[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/cython[${PYTHON_USEDEP}]
+	doc? (
+		>=dev-python/alabaster-0.6.2[${PYTHON_USEDEP}]
+		dev-python/sphinxcontrib-asyncio[${PYTHON_USEDEP}]
+		dev-python/sphinxcontrib-newsfeed[${PYTHON_USEDEP}]
+		dev-python/sphinxcontrib-spelling[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	test? (
+		${CDEPEND}
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		www-servers/gunicorn[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="${CDEPEND}"
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	PYTHONPATH="${PWD}:${PYTHONPATH}" ${PYTHON} -m pytest tests/ || die "Tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+
+	distutils-r1_python_install_all
+}