dev-python/astroquery: version bump

Package-Manager: Portage-2.3.6, Repoman-2.3.2

1 files changed, 61 insertions, 0 deletions

diff --git a/dev-python/astroquery/astroquery-0.3.6.ebuild b/dev-python/astroquery/astroquery-0.3.6.ebuild
new file mode 100644
index 000000000000..1923b8dd52a1
--- /dev/null
+++ b/dev-python/astroquery/astroquery-0.3.6.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit distutils-r1 xdg-utils virtualx
+
+DESCRIPTION="Collection of packages to access online astronomical resources"
+HOMEPAGE="https://github.com/astropy/astroquery"
+SRC_URI="https://github.com/astropy/astroquery/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="doc test"
+
+DOCS=( README.rst )
+
+PYTHON_REQ_USE="test? ( tk )"
+
+RDEPEND="
+	dev-python/astropy[${PYTHON_USEDEP}]
+	dev-python/astropy-helpers[${PYTHON_USEDEP}]
+	dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
+	dev-python/html5lib[${PYTHON_USEDEP}]
+	dev-python/keyring[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/aplpy[${PYTHON_USEDEP}]
+			dev-python/pyregion[${PYTHON_USEDEP}]
+			dev-python/pytest[${PYTHON_USEDEP}] )"
+
+python_prepare_all() {
+	sed -i -e '/auto_use/s/True/False/' setup.cfg || die
+	xdg_environment_reset
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	virtx esetup.py test
+}
+
+python_compile_all() {
+	if use doc; then
+		python_setup
+		VARTEXFONTS="${T}"/fonts \
+			MPLCONFIGDIR="${BUILD_DIR}" \
+			PYTHONPATH="${BUILD_DIR}"/lib \
+			esetup.py build_sphinx
+	fi
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}