dev-python/{CommonMark → commonmark}

Rename dev-python/CommonMark following upstream decision to switch
to lowercase package name.

Signed-off-by: Michał Górny <mgorny@gentoo.org>

4 files changed, 104 insertions, 0 deletions

diff --git a/dev-python/commonmark/Manifest b/dev-python/commonmark/Manifest
new file mode 100644
index 000000000000..5c0753d322e9
--- /dev/null
+++ b/dev-python/commonmark/Manifest
@@ -0,0 +1,2 @@
+DIST CommonMark-0.5.4.tar.gz 120316 BLAKE2B 47904d101d9d0e3759f82c28a4b80edfc0ed12cf0888e4915339118e496322cf0791d8a46d2edddca0d1794e82a9647cc22cbcfcc2d385a740c7c31cb8251659 SHA512 1983714a50a627f30f86af0d02dad9e52cb7b0ffce29691d0e740f587e599ead6de2412d72b895b7df772e1c81e171e56dfecaf593e611af65bd5798632a98ad
+DIST CommonMark-0.7.5.tar.gz 88702 BLAKE2B fc80d9e739d27f7e5dbf539b624c2fc2e700e61b17d0335c3234fc0fa0d3738e9117a8ca29e7a6bbaa6cd0d58b112defb6e19a7efce3ca57ca25c8ce67b2d3d2 SHA512 b0e3c4fea6c99b51c541054ecfe887935c2cc517a82df86da1d9cb4914189652326ec5b543cbbcb40ec43e5e09c285c47f5304ca1907764692e659c540591bdd
diff --git a/dev-python/commonmark/commonmark-0.5.4.ebuild b/dev-python/commonmark/commonmark-0.5.4.ebuild
new file mode 100644
index 000000000000..630fd63052eb
--- /dev/null
+++ b/dev-python/commonmark/commonmark-0.5.4.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit distutils-r1
+
+MY_PN=CommonMark
+MY_P=${MY_PN}-${PV}
+DESCRIPTION="Python parser for the CommonMark Markdown spec"
+HOMEPAGE="https://github.com/rtfd/CommonMark-py"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 ~arm64 x86 ~amd64-linux ~x86-linux"
+IUSE=""
+
+RDEPEND="
+	dev-python/future[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	dev-python/hypothesis[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+S=${WORKDIR}/${MY_P}
+
+# unrestrict for versions >= 0.7.2
+RESTRICT=test
+
+python_test() {
+	LC_ALL='en_US.utf8' LC_CTYPE='en_US.utf8' LANG=en_US.utf8 PYTHONIOENCODING=UTF-8 \
+	esetup.py test
+}
diff --git a/dev-python/commonmark/commonmark-0.7.5.ebuild b/dev-python/commonmark/commonmark-0.7.5.ebuild
new file mode 100644
index 000000000000..52faefc635f9
--- /dev/null
+++ b/dev-python/commonmark/commonmark-0.7.5.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6,3_7} )
+
+inherit distutils-r1
+
+MY_PN=CommonMark
+MY_P=${MY_PN}-${PV}
+DESCRIPTION="Python parser for the CommonMark Markdown spec"
+HOMEPAGE="https://github.com/rtfd/CommonMark-py"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="test"
+
+RDEPEND="
+	dev-python/future[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	test? (
+		>=dev-python/hypothesis-3.7.1[${PYTHON_USEDEP}]
+	)
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+S=${WORKDIR}/${MY_P}
+
+python_test() {
+	PYTHONIOENCODING='utf8' \
+	esetup.py test
+}
+
+src_prepare() {
+	default
+	# Fix file collision with app-text/cmark, see bug #627034
+	sed -i -e "s:'cmark\( = CommonMark.cmark\:main'\):'cmark.py\1:" \
+		setup.py || die
+}
+
+pkg_postinst() {
+	ewarn "/usr/bin/cmark has been renamed to /usr/bin/cmark.py due file"
+	ewarn "collision with app-text/cmark (see bug #627034)"
+}
diff --git a/dev-python/commonmark/metadata.xml b/dev-python/commonmark/metadata.xml
new file mode 100644
index 000000000000..fc5b696a8da1
--- /dev/null
+++ b/dev-python/commonmark/metadata.xml
@@ -0,0 +1,19 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <longdescription lang="en">
+    Pure Python port of jgm’s commonmark.js, a Markdown parser and
+    renderer for the CommonMark specification, using only native
+    modules. Once both this project and the CommonMark specification
+    are stable we will release the first 1.0 version and attempt to
+    keep up to date with changes in commonmark.js.
+  </longdescription>
+  <upstream>
+    <remote-id type="pypi">CommonMark</remote-id>
+    <remote-id type="github">rtfd/CommonMark.py</remote-id>
+  </upstream>
+</pkgmetadata>