dev-python/flask-security: Bump to 3.4.4

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 74 insertions, 0 deletions

diff --git a/dev-python/flask-security/Manifest b/dev-python/flask-security/Manifest
index 349f4938ec38..7ddf3fafde64 100644
--- a/dev-python/flask-security/Manifest
+++ b/dev-python/flask-security/Manifest
@@ -1,2 +1,3 @@
 DIST Flask-Security-3.0.0.tar.gz 160367 BLAKE2B c2e1449dc2807c2c40519fa3afb894157e17ecc9ff3f6dcf5ef0d02839a5988f827afd26c1d31af86d5e240e0ea8bfb8ed86354bb6a83535436b08721cac8f26 SHA512 09b94f0850372513add5c054c07aa465ecb95e8d1c414647e3ebee571ec08c94a29f0c138d092c02a55e242c422bc53f929ca066d671c082dcb29834ac753984
 DIST flask-security-3.4.3.gh.tar.gz 346540 BLAKE2B ab3b037282bc5b7777ceeaaaf869996f471bc3b954f0b2cf6d17ba44d4014c8c3ac8e34618bc7347bbd1cd6b1c649b49407cb05aad9bd748191c08b7326f679a SHA512 23ad8bc91df418361a556827ff8369777f3716dfd1c97fef6237ba9cb07813eac4033eb3fed80e9ebadeab4f2d2a956b5a652bec80825f939a9fc7d817aa3d90
+DIST flask-security-3.4.4.gh.tar.gz 348525 BLAKE2B 77a851c2549be9ce8612e3b186ad2d83d272b277f286885da491f3f0fe99e8836d145749ae137f1e75625c34b2214270ba4d24f1bfaa514012064dd38f083230 SHA512 1c1a4f079199704d7a2a4e11351cd199e3a790f5d0c7f68b240c299e83b129227fac4ca00caf45401efbf14520c1d65d3b710b85e8f53b495283b94a164f97a2
diff --git a/dev-python/flask-security/flask-security-3.4.4.ebuild b/dev-python/flask-security/flask-security-3.4.4.ebuild
new file mode 100644
index 000000000000..18073cabe061
--- /dev/null
+++ b/dev-python/flask-security/flask-security-3.4.4.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} )
+inherit distutils-r1
+
+DESCRIPTION="Simple security for Flask apps"
+HOMEPAGE="
+	https://github.com/Flask-Middleware/flask-security/
+	https://pypi.org/project/Flask-Security-Too/"
+SRC_URI="
+	https://github.com/Flask-Middleware/flask-security/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/cachetools[${PYTHON_USEDEP}]
+	>=dev-python/flask-1.1.1[${PYTHON_USEDEP}]
+	>=dev-python/flask-babelex-0.9.3[${PYTHON_USEDEP}]
+	>=dev-python/flask-login-0.4.1[${PYTHON_USEDEP}]
+	>=dev-python/flask-principal-0.4.0[${PYTHON_USEDEP}]
+	>=dev-python/flask-wtf-0.14.2[${PYTHON_USEDEP}]
+	>=dev-python/itsdangerous-1.1.0[${PYTHON_USEDEP}]
+	>=dev-python/passlib-1.7.2[${PYTHON_USEDEP}]
+	>=dev-python/python-email-validator-1.0.5[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	dev-python/Babel[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/argon2-cffi-19.1.0[${PYTHON_USEDEP}]
+		>=dev-python/bcrypt-3.1.5[${PYTHON_USEDEP}]
+		>=dev-python/cryptography-2.3.1[${PYTHON_USEDEP}]
+		>=dev-python/flask-mail-0.9.1[${PYTHON_USEDEP}]
+		>=dev-python/flask-mongoengine-0.9.5[${PYTHON_USEDEP}]
+		>=dev-python/flask-sqlalchemy-2.3[${PYTHON_USEDEP}]
+		>=dev-python/mongomock-3.19.0[${PYTHON_USEDEP}]
+		>=dev-python/peewee-3.11.2[${PYTHON_USEDEP}]
+		>=dev-python/phonenumbers-8.11.1[${PYTHON_USEDEP}]
+		>=dev-python/psycopg-2.8.4:2[${PYTHON_USEDEP}]
+		>=dev-python/pymysql-0.9.3[${PYTHON_USEDEP}]
+		>=dev-python/pyqrcode-1.2[${PYTHON_USEDEP}]
+		>=dev-python/zxcvbn-4.4.28[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			>=dev-python/pony-0.7.11[${PYTHON_USEDEP}]
+		' python3_{6,7})
+	)"
+
+distutils_enable_tests pytest
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.4.3-optional-deps.patch
+)
+
+src_prepare() {
+	sed -i -e '/setup_requires/d' setup.py || die
+	sed -e 's:--cov flask_security::' \
+		-e 's:--cov-report term-missing::' \
+		-e 's:--black::' \
+		-e 's:--flake8::' \
+		-e 's:--cache-clear::' \
+		-i pytest.ini || die
+	distutils-r1_src_prepare
+}
+
+python_configure_all() {
+	esetup.py compile_catalog
+}