dev-python/hpack: Bump 3.0.0 to python 3.10

Signed-off-by: Ekaterina Vaartis <vaartis@kotobank.ch>
Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 14 insertions, 16 deletions

diff --git a/dev-python/hpack/hpack-3.0.0.ebuild b/dev-python/hpack/hpack-3.0.0.ebuild
index b52fcbda7054..99cf18dfe91d 100644
--- a/dev-python/hpack/hpack-3.0.0.ebuild
+++ b/dev-python/hpack/hpack-3.0.0.ebuild
@@ -1,42 +1,40 @@
 # Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
-PYTHON_COMPAT=( python3_{7,8,9})
+EAPI=7
+PYTHON_COMPAT=( python3_{7..10} )
 
 inherit distutils-r1
 
 DESCRIPTION="Pure-Python HPACK header compression"
-HOMEPAGE="https://python-hyper.org/hpack/en/latest/ https://pypi.org/project/hpack/"
+HOMEPAGE="
+	https://python-hyper.org/hpack/en/latest/
+	https://pypi.org/project/hpack/"
 SRC_URI="https://github.com/python-hyper/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
 
 LICENSE="MIT"
 SLOT="0"
 KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~mips ppc ppc64 ~riscv ~s390 sparc x86"
-IUSE="test"
-RESTRICT="!test? ( test )"
 
-RDEPEND=""
 # dev-python/pytest-relaxed causes tests to fail
-DEPEND="${RDEPEND}
+BDEPEND="
 	test? (
-		>=dev-python/pytest-2.9.2[${PYTHON_USEDEP}]
 		>=dev-python/hypothesis-3.4.2[${PYTHON_USEDEP}]
 		!!dev-python/pytest-relaxed[${PYTHON_USEDEP}]
 	)
 "
 
+distutils_enable_tests pytest
+
 PATCHES=(
 	"${FILESDIR}"/hpack-3.0.0-hypothesis-healthcheck.patch
 )
 
-python_prepare_all() {
-	# Remove a test that is not part of the mainstream tests
-	# Also, it's data directory is not included in the release
-	rm test/test_hpack_integration.py || die
-	distutils-r1_python_prepare_all
-}
-
 python_test() {
-	pytest -vv hpack test || die "Tests fail with ${EPYTHON}"
+	local deselect=(
+		# relies on outdated exception strings
+		test/test_table.py::TestHeaderTable::test_get_by_index_out_of_range
+	)
+
+	epytest hpack test ${deselect[@]/#/--deselect }
 }