dev-python/jaraco-functools: bump to 3.1.0

Use distutils_enable_tests to make ebuild thinner.

Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Louis Sautier <sbraz@gentoo.org>

1 files changed, 47 insertions, 0 deletions

diff --git a/dev-python/jaraco-functools/jaraco-functools-3.1.0.ebuild b/dev-python/jaraco-functools/jaraco-functools-3.1.0.ebuild
new file mode 100644
index 000000000000..22409d35da9a
--- /dev/null
+++ b/dev-python/jaraco-functools/jaraco-functools-3.1.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy3 python3_{6..9} )
+
+inherit distutils-r1
+
+MY_PN="${PN/-/.}"
+DESCRIPTION="Additional functions used by other projects by developer jaraco"
+HOMEPAGE="https://github.com/jaraco/jaraco.functools"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/toml[${PYTHON_USEDEP}]
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/jaraco-classes[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs \
+	">=dev-python/jaraco-packaging-3.2" \
+	">=dev-python/rst-linker-1.9"
+distutils_enable_tests pytest
+
+python_test() {
+	# Override pytest options to skip flake8
+	PYTHONPATH=. pytest -vv --override-ini="addopts=--doctest-modules" \
+		|| die "tests failed with ${EPYTHON}"
+}
+
+# https://wiki.gentoo.org/wiki/Project:Python/Namespace_packages#File_collisions_between_pkgutil-style_packages
+python_install() {
+	rm "${BUILD_DIR}"/lib/jaraco/__init__.py || die
+	# note: eclass may default to --skip-build in the future
+	distutils-r1_python_install --skip-build
+}