dev-python/pycryptodome: Remove python2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 41 insertions, 0 deletions

diff --git a/dev-python/pycryptodome/pycryptodome-3.9.8-r1.ebuild b/dev-python/pycryptodome/pycryptodome-3.9.8-r1.ebuild
new file mode 100644
index 000000000000..4ae0c12c89b5
--- /dev/null
+++ b/dev-python/pycryptodome/pycryptodome-3.9.8-r1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="A self-contained cryptographic library for Python"
+HOMEPAGE="https://www.pycryptodome.org https://github.com/Legrandin/pycryptodome https://pypi.org/project/pycryptodome/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD-2 Unlicense"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~mips ppc ppc64 s390 sparc x86 ~ppc-aix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE=""
+
+RDEPEND="dev-libs/gmp:0
+	virtual/python-cffi[${PYTHON_USEDEP}]
+	!dev-python/pycrypto"
+BDEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}/pycryptodome-3.9.4-parallel-make.patch"
+)
+
+distutils_enable_tests setup.py
+
+python_prepare_all() {
+	# parallel make fixes
+	#  Multiple targets were compiling the same file, setuptools doesn't
+	#  understand this and you get race conditions where a file gets
+	#  overwritten while it's linking. This makes the files look like separate
+	#  files so this race won't happen
+	ln src/blowfish.c src/blowfish_eks.c || die
+	ln src/mont.c src/mont_math.c || die
+
+	distutils-r1_python_prepare_all
+}