dev-python/pyopenssl: add patch for LibreSSL

Closes: https://bugs.gentoo.org/757738
Package-Manager: Portage-3.0.11, Repoman-3.0.2
Signed-off-by: Stefan Strogin <steils@gentoo.org>

1 files changed, 53 insertions, 0 deletions

diff --git a/dev-python/pyopenssl/pyopenssl-20.0.0-r1.ebuild b/dev-python/pyopenssl/pyopenssl-20.0.0-r1.ebuild
new file mode 100644
index 000000000000..0e4a096a48ac
--- /dev/null
+++ b/dev-python/pyopenssl/pyopenssl-20.0.0-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 flag-o-matic
+
+MY_PN=pyOpenSSL
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Python interface to the OpenSSL library"
+HOMEPAGE="
+	https://www.pyopenssl.org/
+	https://pypi.org/project/pyOpenSSL/
+	https://github.com/pyca/pyopenssl/
+"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/six-1.5.2[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-3.2[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	test? (
+		virtual/python-cffi[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/pretend[${PYTHON_USEDEP}]
+		>=dev-python/pytest-3.0.1[${PYTHON_USEDEP}]
+	)"
+
+PATCHES=( "${FILESDIR}"/${P}-libressl.patch )
+
+distutils_enable_sphinx doc \
+	dev-python/sphinx_rtd_theme
+
+python_prepare_all() {
+	# Requires network access
+	sed -i -e 's/test_set_default_verify_paths/_&/' tests/test_ssl.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	TZ=UTC pytest -vv || die "Testing failed with ${EPYTHON}" # Fixes bug #627530
+}