dev-python/python-glanceclient: 2.10.0 bup

Package-Manager: Portage-2.3.27, Repoman-2.3.9

2 files changed, 78 insertions, 0 deletions

diff --git a/dev-python/python-glanceclient/Manifest b/dev-python/python-glanceclient/Manifest
index aa8b67619a48..8d2050712b6c 100644
--- a/dev-python/python-glanceclient/Manifest
+++ b/dev-python/python-glanceclient/Manifest
@@ -1,2 +1,3 @@
+DIST python-glanceclient-2.10.0.tar.gz 180299 BLAKE2B 0d97626361ad7fc2c688f5da6af6d49bf6e078f715560b4ac93725f8ea6df895e7eed0e44bf69399c973978af22ebaef3d371ae19026cff7fb2bd896c8be30d2 SHA512 9132493559d7a7b6de62e5ec1bdcd7a2dcf408c00bb0cfaccb6e11829975d468bfe68feabd71fdf8cc0d28a2c5c549945816aa14c9469314ffafd3d39b9c2da6
 DIST python-glanceclient-2.8.0.tar.gz 177172 BLAKE2B 0772b7e2b788b63bb590c8354dbad2c4e0bbd731f790f36916aeb154a44474f979961195d307e45149bccd2a58e1df72c48aa0593d6972c606b393f1202ee440 SHA512 257eaf1d548a3a6277b9c80e8b23b9ae4231586307c43a064754c227f3e3c872451ec0469aca931638ea0f7c9920892878c677b144dc72bad215c38d375a63d3
 DIST python-glanceclient-2.9.1.tar.gz 175836 BLAKE2B f559bff0b4ae1d1782bb06f9bb8b0188d9e78b83afb52a07245f8d9694bfe88e52718d3279f8b2b7d32acdd3cc86d507154bc9bcf716206696144345f4766249 SHA512 0dae48a5673ed779c0a4136896f5e74dcde489a5dfee55295f65d4b74dbe4680b1669570d0fe5011ca5282d0b6057ebc9261e5a06cff0b09fe41fa88529c3947
diff --git a/dev-python/python-glanceclient/python-glanceclient-2.10.0.ebuild b/dev-python/python-glanceclient/python-glanceclient-2.10.0.ebuild
new file mode 100644
index 000000000000..bffb4cc4e44e
--- /dev/null
+++ b/dev-python/python-glanceclient/python-glanceclient-2.10.0.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+
+inherit distutils-r1
+
+DESCRIPTION="A client for the OpenStack Glance API"
+HOMEPAGE="https://github.com/openstack/python-glanceclient"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc test"
+REQUIRED_USE="test? ( doc )"
+
+CDEPEND=">=dev-python/pbr-2.0.0[${PYTHON_USEDEP}]
+	!~dev-python/pbr-2.1.0"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	${CDEPEND}
+	test? (
+		>=dev-python/coverage-4.0[${PYTHON_USEDEP}]
+		!~dev-python/coverage-4.4[${PYTHON_USEDEP}]
+		>=dev-python/mock-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/ordereddict-1.1[$(python_gen_usedep 'python2_7')]
+		>=dev-python/os-client-config-1.28.0[${PYTHON_USEDEP}]
+		>=dev-python/openstackdocstheme-1.18.1[${PYTHON_USEDEP}]
+		>=dev-python/reno-2.5.0[${PYTHON_USEDEP}]
+		>=dev-python/testrepository-0.0.18[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/requests-mock-1.1.0[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/openstackdocstheme-1.18.1[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.6.2[${PYTHON_USEDEP}]
+		!~dev-python/sphinx-1.6.6[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="
+	${CDEPEND}
+	>=dev-python/prettytable-0.7.1[${PYTHON_USEDEP}]
+	<dev-python/prettytable-0.8[${PYTHON_USEDEP}]
+	>=dev-python/keystoneauth-3.3.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.14.2[${PYTHON_USEDEP}]
+	>=dev-python/warlock-1.2.0[${PYTHON_USEDEP}]
+	<dev-python/warlock-2[${PYTHON_USEDEP}]
+	>=dev-python/six-1.10.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-3.33.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
+	>=dev-python/wrapt-1.7.0[${PYTHON_USEDEP}]
+	>=dev-python/pyopenssl-16.2.0[${PYTHON_USEDEP}]
+"
+
+python_prepare_all() {
+	sed -e 's:intersphinx_mapping:_&:' -i doc/source/conf.py || die
+	sed -i '/^hacking/d' test-requirements.txt || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && esetup.py build_sphinx
+}
+
+python_test() {
+	testr init
+	testr run || die "testsuite failed under python2.7"
+	flake8 tests && einfo "run flake8 over tests folder passed" || die
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/build/html/. )
+	distutils-r1_python_install_all
+}