dev-python/qscintilla-python: support building against Qt5/PyQt5

Gentoo-Bug: 541604

Package-Manager: Portage-2.3.3, Repoman-2.3.1

3 files changed, 87 insertions, 2 deletions

diff --git a/dev-python/qscintilla-python/qscintilla-python-2.9.2-r1.ebuild b/dev-python/qscintilla-python/qscintilla-python-2.9.2-r1.ebuild
index b1671d7ae8ce..02e93095fa1e 100644
--- a/dev-python/qscintilla-python/qscintilla-python-2.9.2-r1.ebuild
+++ b/dev-python/qscintilla-python/qscintilla-python-2.9.2-r1.ebuild
@@ -53,7 +53,7 @@ src_configure() {
 		"${myconf[@]}" || die
 
 		# Run eqmake4 to respect toolchain, build flags, and prevent stripping
-		eqmake4
+		eqmake4 -recursive
 	}
 	python_foreach_impl run_in_build_dir configuration
 }
diff --git a/dev-python/qscintilla-python/qscintilla-python-2.9.4-r1.ebuild b/dev-python/qscintilla-python/qscintilla-python-2.9.4-r1.ebuild
new file mode 100644
index 000000000000..8c6671955d30
--- /dev/null
+++ b/dev-python/qscintilla-python/qscintilla-python-2.9.4-r1.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 python3_{4,5} )
+
+inherit python-r1 qmake-utils
+
+MY_P=QScintilla_gpl-${PV}
+
+DESCRIPTION="Python bindings for Qscintilla"
+HOMEPAGE="http://www.riverbankcomputing.com/software/qscintilla/intro"
+SRC_URI="mirror://sourceforge/pyqt/${MY_P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ia64 ~ppc64 ~sparc ~x86"
+IUSE="debug +qt4 qt5"
+
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	^^ ( qt4 qt5 )
+"
+
+DEPEND="
+	${PYTHON_DEPS}
+	>=dev-python/sip-4.19:=[${PYTHON_USEDEP}]
+	~x11-libs/qscintilla-${PV}:=[qt4(-)?,qt5(+)?]
+	qt4? (
+		>=dev-python/PyQt4-4.11.3[X,${PYTHON_USEDEP}]
+		dev-qt/qtcore:4
+		dev-qt/qtgui:4
+	)
+	qt5? (
+		dev-python/PyQt5[gui,printsupport,widgets,${PYTHON_USEDEP}]
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtprintsupport:5
+		dev-qt/qtwidgets:5
+	)
+"
+RDEPEND="${DEPEND}"
+
+S=${WORKDIR}/${MY_P}/Python
+
+src_prepare() {
+	default
+	python_copy_sources
+}
+
+src_configure() {
+	local my_qt_ver=$(usex qt5 5 4)
+
+	configuration() {
+		local myconf=(
+			"${PYTHON}"
+			configure.py
+			--qmake="$(qt${my_qt_ver}_get_bindir)"/qmake
+			--destdir="$(python_get_sitedir)"/PyQt${my_qt_ver}
+			--sip-incdir="$(python_get_includedir)"
+			--pyqt=PyQt${my_qt_ver}
+			$(usex debug '--debug --trace' '')
+			--verbose
+		)
+		echo "${myconf[@]}"
+		"${myconf[@]}" || die
+
+		# Run eqmake to respect toolchain, build flags, and prevent stripping
+		eqmake${my_qt_ver} -recursive
+	}
+	python_foreach_impl run_in_build_dir configuration
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+	installation() {
+		emake INSTALL_ROOT="${D}" install
+		python_optimize
+	}
+	python_foreach_impl run_in_build_dir installation
+}
diff --git a/dev-python/qscintilla-python/qscintilla-python-2.9.4.ebuild b/dev-python/qscintilla-python/qscintilla-python-2.9.4.ebuild
index 444c5883c0da..6174d4c0a67b 100644
--- a/dev-python/qscintilla-python/qscintilla-python-2.9.4.ebuild
+++ b/dev-python/qscintilla-python/qscintilla-python-2.9.4.ebuild
@@ -53,7 +53,7 @@ src_configure() {
 		"${myconf[@]}" || die
 
 		# Run eqmake4 to respect toolchain, build flags, and prevent stripping
-		eqmake4
+		eqmake4 -recursive
 	}
 	python_foreach_impl run_in_build_dir configuration
 }