dev-python/qstylizer: new dep of spyder

Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Andrew Ammerlaan <andrewammerlaan@riseup.net>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

3 files changed, 69 insertions, 0 deletions

diff --git a/dev-python/qstylizer/Manifest b/dev-python/qstylizer/Manifest
new file mode 100644
index 000000000000..f1956f81d591
--- /dev/null
+++ b/dev-python/qstylizer/Manifest
@@ -0,0 +1 @@
+DIST qstylizer-0.1.10.tar.gz 20683 BLAKE2B aa12addac6cbe1ebf043d70189683feda87db3a8c2aa3604a04a969f638647ba32eaf7d156559b8af151136aaca784f26025746d9f3e574ad6eb777801bcf44a SHA512 1a747c2a0d5ce0acd220f528bc54c84c723f50bf39fc8d818f6a5475105319f46700d2f00bc5c0f14de8f0caaee0ab8904a379a3e697ca68d00ef62ec3408b2b
diff --git a/dev-python/qstylizer/metadata.xml b/dev-python/qstylizer/metadata.xml
new file mode 100644
index 000000000000..4db1da22a045
--- /dev/null
+++ b/dev-python/qstylizer/metadata.xml
@@ -0,0 +1,16 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person" proxied="yes">
+		<email>andrewammerlaan@riseup.net</email>
+		<name>Andrew Ammerlaan</name>
+	</maintainer>
+	<maintainer type="project" proxied="proxy">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="pypi">qstylizer</remote-id>
+	</upstream>
+</pkgmetadata>
diff --git a/dev-python/qstylizer/qstylizer-0.1.10.ebuild b/dev-python/qstylizer/qstylizer-0.1.10.ebuild
new file mode 100644
index 000000000000..52a525de7eed
--- /dev/null
+++ b/dev-python/qstylizer/qstylizer-0.1.10.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8} )
+
+inherit distutils-r1
+
+DESCRIPTION="Stylesheet Generator for PyQt5/PySide2"
+HOMEPAGE="https://github.com/blambright/qstylizer"
+SRC_URI="https://github.com/blambright/${PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/tinycss-0.4[${PYTHON_USEDEP}]
+	<dev-python/tinycss-1[${PYTHON_USEDEP}]
+	>=dev-python/inflection-0.3.0[${PYTHON_USEDEP}]
+	<dev-python/inflection-1[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	dev-python/pbr[${PYTHON_USEDEP}]
+	dev-vcs/git
+	test? (
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx doc dev-python/sphinx_rtd_theme dev-python/sphinxcontrib-autoprogram
+
+python_prepare_all(){
+	# Exception: Versioning for this project requires either an sdist tarball, or access to an
+	# upstream git repository. It's also possible that there is a mismatch between the package
+	# name in setup.cfg and the argument given to pbr.version.VersionInfo. Project name qstylizer
+	# was given, but was not able to be found.
+	#
+	# There are no tarballs on PyPI, so we do this as a workaround
+	git init || die
+	git config user.email "larry@gentoo.org" || die
+	git config user.name "Larry the Cow" || die
+	git add . || die
+	git commit -m "init" || die
+	git tag -a "${PV}" -m "${PV}" || die
+
+	distutils-r1_python_prepare_all
+}