dev-python/spyder: drop 5.5.3

Signed-off-by: Andrew Ammerlaan <andrewammerlaan@gentoo.org>

2 files changed, 0 insertions, 196 deletions

diff --git a/dev-python/spyder/Manifest b/dev-python/spyder/Manifest
index 0cd3683185cd..1a5fe8c9e0bc 100644
--- a/dev-python/spyder/Manifest
+++ b/dev-python/spyder/Manifest
@@ -1,6 +1,4 @@
-DIST spyder-5.5.3.gh.tar.gz 16254522 BLAKE2B 4f6fcaf68a451ff2253cdda1008c854374ef96f42d4edd8614dceee61d931cabe204a3d2c1a8141ab74b165a2dc63879cc8192a4cf3c29f0418fb0d648d12f15 SHA512 001b6208ce937efb9d7aa7225659efaad921b55a6ec0d464496a93f5bd31980724ab98706f4f3e24130ea6b8943a7ad203efe47f32fc0597c15c603b492ccc3d
 DIST spyder-5.5.4.gh.tar.gz 16258160 BLAKE2B 4f29db0805e1d7eed33497df0b28754cd873cfa5c6bd6c7955efc881000498a7527e413de5107ca4414f2dcbf0aa55903b1bf496626e7b470942cc5142abc152 SHA512 4f68d1edc2901b4cffb67943c782ccd89e923722579ec4144064de2ec1b6bbf89f831feb3eb58a7adf7c403efc7d2529c38017b423bb32709170915792f4deb2
 DIST spyder-6.0.0_alpha4.gh.tar.gz 15503538 BLAKE2B ee896fe2c3c2afd464a8c86204f770ef08ff2fdfc68f7431d2706f76516b6e2b31c9cda8df3236cb3b85799d67f983fbbbfcdc92400a2a88f1efdcd166622f50 SHA512 8ff36feecf6ce99d90ec07fc0cc3ecab075af4e36d64ba650316a46d1f79ca1a08ca7eb2b48dee6e5eddaaafaff14445f0b687742e9a439c3e4def098e489879
 DIST spyder-docs-0aa81d44ec6490c155be1bb1acca0a27328b12e0.gh.tar.gz 94895731 BLAKE2B 468412372bf2f70f838fa89dc1b88997fa2d9d92e36d6a5abac736b6b5f2782f25121b18b876c7c6e2af9d7eda433aaccd017c2e8c8c06a223420f0ce9684fc1 SHA512 9ac0f930a1a864e81e4181f101449a6506728d0d89254409a58e68bc17a3de39f4d1bf329f11da433d8ee4f3122faf3b337654d011263a70b253459e9562e923
 DIST spyder-docs-32efdaebc11dab0b8e0767717342b7d306dc06ea.gh.tar.gz 94897009 BLAKE2B 30e0b42e34bddb60d8fc986183a363b71455067bc7f4411cb75a00c5758e87501ee07ad0b484caed2aa3cf91153be814c7faf935be8665b6984bce38ebcd0be2 SHA512 9f9aa56ab27aed8d27c3d653119d5c5454b4317a78a7ff27715d91cac9dec79143db85d4f1c87b10fa821eb33abc043912df308fa6c84ade59539bd633eefbd2
-DIST spyder-docs-390681bc6557a051579337723c11b835d3855222.gh.tar.gz 94896996 BLAKE2B 62b7709c8a587271758a51169b269771b4b56bf32218ee3beda66c7dc7836bff89df518af61bcbb03a97374b18d4107c47f33661b388dfc92d66a93482642371 SHA512 9456ba1b891b9668006ecb1f2baa6ecfbe4df944d8bf0519c3bdf346a13b25cb1b4d272421e4b96593bc2dfc8bce2a4aa89380d2bda53b3d907f13c31a21abf7
diff --git a/dev-python/spyder/spyder-5.5.3.ebuild b/dev-python/spyder/spyder-5.5.3.ebuild
deleted file mode 100644
index 7cc3cfb2d35c..000000000000
--- a/dev-python/spyder/spyder-5.5.3.ebuild
+++ /dev/null
@@ -1,194 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{10..12} )
-DISTUTILS_USE_PEP517=setuptools
-
-inherit distutils-r1 optfeature virtualx xdg
-
-# Commit of documentation to fetch
-DOCS_PV="390681bc6557a051579337723c11b835d3855222"
-
-DESCRIPTION="The Scientific Python Development Environment"
-HOMEPAGE="
-	https://www.spyder-ide.org/
-	https://github.com/spyder-ide/spyder/
-	https://pypi.org/project/spyder/
-"
-SRC_URI="
-	https://github.com/spyder-ide/${PN}/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz
-	https://github.com/spyder-ide/${PN}-docs/archive/${DOCS_PV}.tar.gz -> ${PN}-docs-${DOCS_PV}.gh.tar.gz
-"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~arm64 ~x86"
-
-RDEPEND="
-	>=dev-python/atomicwrites-1.2.0[${PYTHON_USEDEP}]
-	>=dev-python/chardet-2.0.0[${PYTHON_USEDEP}]
-	>=dev-util/cookiecutter-1.6.0[${PYTHON_USEDEP}]
-	>=dev-python/diff-match-patch-20181111[${PYTHON_USEDEP}]
-	>=dev-python/intervaltree-3.0.2[${PYTHON_USEDEP}]
-	>=dev-python/jellyfish-0.7[${PYTHON_USEDEP}]
-	>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
-	>=dev-python/keyring-17.0.0[${PYTHON_USEDEP}]
-	>=dev-python/nbconvert-4.0[${PYTHON_USEDEP}]
-	>=dev-python/numpydoc-0.6.0[${PYTHON_USEDEP}]
-	>=dev-python/pexpect-4.4.0[${PYTHON_USEDEP}]
-	>=dev-python/pickleshare-0.4[${PYTHON_USEDEP}]
-	>=dev-python/psutil-5.3[${PYTHON_USEDEP}]
-	>=dev-python/pygments-2.0[${PYTHON_USEDEP}]
-	>=dev-python/pylint-venv-3.0.2[${PYTHON_USEDEP}]
-	>=dev-python/python-lsp-black-2.0.0[${PYTHON_USEDEP}]
-	<dev-python/python-lsp-black-3[${PYTHON_USEDEP}]
-	>=dev-python/pyls-spyder-0.4.0[${PYTHON_USEDEP}]
-	>=dev-python/pyxdg-0.26[${PYTHON_USEDEP}]
-	>=dev-python/pyzmq-24.0.0[${PYTHON_USEDEP}]
-	>=dev-python/qdarkstyle-3.2[${PYTHON_USEDEP}]
-	<dev-python/qdarkstyle-3.3[${PYTHON_USEDEP}]
-	>=dev-python/qstylizer-0.2.2[${PYTHON_USEDEP}]
-	>=dev-python/qtawesome-1.2.1[${PYTHON_USEDEP}]
-	>=dev-python/qtconsole-5.5.1[${PYTHON_USEDEP}]
-	<dev-python/qtconsole-5.6.0[${PYTHON_USEDEP}]
-	>=dev-python/QtPy-2.1.0[${PYTHON_USEDEP},pyqt5,svg,webengine]
-	>=sci-libs/rtree-0.9.7[${PYTHON_USEDEP}]
-	>=dev-python/sphinx-0.6.6[${PYTHON_USEDEP}]
-	>=dev-python/spyder-kernels-2.5.1[${PYTHON_USEDEP}]
-	<dev-python/spyder-kernels-2.6.0[${PYTHON_USEDEP}]
-	>=dev-python/textdistance-4.2.0[${PYTHON_USEDEP}]
-	>=dev-python/three-merge-0.1.1[${PYTHON_USEDEP}]
-	>=dev-python/watchdog-0.10.3[${PYTHON_USEDEP}]
-"
-
-BDEPEND="
-	test? (
-		dev-python/cython[${PYTHON_USEDEP}]
-		dev-python/flaky[${PYTHON_USEDEP}]
-		dev-python/matplotlib[tk,${PYTHON_USEDEP}]
-		dev-python/pandas[${PYTHON_USEDEP}]
-		dev-python/pillow[${PYTHON_USEDEP}]
-		dev-python/pytest-lazy-fixture[${PYTHON_USEDEP}]
-		dev-python/pytest-mock[${PYTHON_USEDEP}]
-		dev-python/pytest-order[${PYTHON_USEDEP}]
-		dev-python/pytest-qt[${PYTHON_USEDEP}]
-		dev-python/pytest-timeout[${PYTHON_USEDEP}]
-		dev-python/pyyaml[${PYTHON_USEDEP}]
-		dev-python/QtPy[${PYTHON_USEDEP},pyside2,pyqt5]
-		dev-python/scipy[${PYTHON_USEDEP}]
-		dev-python/sympy[${PYTHON_USEDEP}]
-	)"
-
-# Based on the courtesy of Arfrever
-# This patch removes a call to update-desktop-database during build
-# This fails because access is denied to this command during build
-PATCHES=(
-	"${FILESDIR}/${PN}-5.0.0-build.patch"
-	"${FILESDIR}/${PN}-5.2.0-doc-theme-renamed.patch"
-)
-
-DOCS=(
-	"AUTHORS.txt"
-	"Announcements.md"
-	"CHANGELOG.md"
-	"CODE_OF_CONDUCT.md"
-	"CONTRIBUTING.md"
-	"NOTICE.txt"
-	"README.md"
-	"RELEASE.md"
-)
-
-distutils_enable_tests pytest
-distutils_enable_sphinx docs/doc \
-	dev-python/sphinx-panels \
-	dev-python/pydata-sphinx-theme \
-	dev-python/sphinx-multiversion
-
-python_prepare_all() {
-	# move docs into workdir
-	mv ../spyder-docs-${DOCS_PV}* docs || die
-
-	# these dependencies are packaged separately:
-	#    dev-python/spyder-kernels,
-	#    dev-python/python-lsp-server,
-	#    dev-python/qdarkstyle
-	rm -r external-deps/* || die
-	# runs against things packaged in external-deps dir
-	rm conftest.py || die
-
-	# Do not depend on pyqt5<5.16, this dependency is carried by QtPy[pyqt5]
-	# Do not depend on pyqtwebengine<5.16, this dependency is carried by QtPy[webengine]
-	# Do not depend on parso and jedi, this is dependency is carried in python-lsp-server
-	# Do not depend on python-lsp-server, this dependency is carried in pyls-spyder
-	# Do not depend on ipython, this dependency is carried in spyder-kernels
-	# The explicit version requirements only make things more complicated, if e.g.
-	# pyls-spyder gains compatibility with a newer version of python-lsp-server
-	# in a new release it will take time for this information to propagate into
-	# the next spyder release. So just remove the dependency and let the other
-	# ebuilds handle the version requirements to speed things up and prevent
-	# issues such as Bug 803269.
-	sed -i \
-		-e "/'pyqt5[ 0-9<=>.,]*',/d" \
-		-e "/'pyqtwebengine[ 0-9<=>.,]*',/d" \
-		-e "/'python-lsp-server\[all\][ 0-9<=>.,]*',/d" \
-		-e "/'parso[ 0-9<=>.,]*',/d" \
-		-e "/'jedi[ 0-9<=>.,]*',/d" \
-		-e "/'pylint[ 0-9<=>.,]*',/d" \
-		-e "/'qtawesome[ 0-9<=>.,]*',/d" \
-			setup.py || die
-		# -e "/'ipython[ 0-9<=>.,]*',/d" \
-
-	sed -i \
-		-e "/^PYLS_REQVER/c\PYLS_REQVER = '>=0.0.1'" \
-		-e "/^PYLSP_REQVER/c\PYLSP_REQVER = '>=0.0.1'" \
-		-e "/^PARSO_REQVER/c\PARSO_REQVER = '>=0.0.1'" \
-		-e "/^JEDI_REQVER/c\JEDI_REQVER = '>=0.0.1'" \
-		-e "/^PYLINT_REQVER/c\PYLINT_REQVER = '>=0.0.1'" \
-		-e "/^QTAWESOME_REQVER/c\QTAWESOME_REQVER = '>=0.0.1'" \
-			spyder/dependencies.py || die
-		# -e "/^IPYTHON_REQVER/c\IPYTHON_REQVER = '>=0.0.1'" \
-
-	# do not check deps, fails because we removed dependencies above
-	sed -i -e 's:test_dependencies_for_spyder_setup_install_requires_in_sync:_&:' \
-		spyder/tests/test_dependencies_in_sync.py || die
-
-	# can't check for update, need network
-	rm spyder/workers/tests/test_update.py || die
-
-	# skip online test
-	rm spyder/widgets/github/tests/test_github_backend.py || die
-
-	distutils-r1_python_prepare_all
-}
-
-# Calling pytest directly somehow passes the pytest arguments to spyder
-# causing an invalid argument error
-python_test() {
-	virtx "${EPYTHON}" runtests.py
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-
-	optfeature "2D/3D plotting in the Python and IPython consoles" dev-python/matplotlib
-	optfeature "View and edit DataFrames and Series in the Variable Explorer" dev-python/pandas
-	optfeature "View and edit two or three dimensional arrays in the Variable Explorer" dev-python/numpy
-	optfeature "Symbolic mathematics in the IPython console" dev-python/sympy
-	optfeature "Import Matlab workspace files in the Variable Explorer" dev-python/scipy
-	optfeature "Run Cython files in the IPython console" dev-python/cython
-	optfeature "The hdf5/h5py plugin" dev-python/h5py
-	optfeature "The line profiler plugin" dev-python/spyder-line-profiler
-	optfeature "Vim key bindings" dev-python/spyder-vim
-	optfeature "Unittest support" dev-python/spyder-unittest
-	optfeature "System terminal inside spyder" dev-python/spyder-terminal
-	optfeature "Jupyter notebook support" dev-python/spyder-notebook
-	# spyder-memory-profiler is not compatible with spyder-5.2+ yet
-	# optfeature "The memory profiler plugin" dev-python/spyder-memory-profiler
-	# spyder-reports not yet updated to >=spyder-4.0.0
-	# optfeature "Markdown reports using Pweave" dev-python/spyder-reports
-	# Plugins with no release yet:
-	# optfeature "Manage virtual environments and packages" dev-python/spyder-env-manager
-	# optfeature "VCS (e.g. git) integration" dev-python/spyder-vcs
-}