dev-python/stevedore: 1.30.1 bump

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Matthew Thode <prometheanfire@gentoo.org>

1 files changed, 65 insertions, 0 deletions

diff --git a/dev-python/stevedore/stevedore-1.30.1.ebuild b/dev-python/stevedore/stevedore-1.30.1.ebuild
new file mode 100644
index 000000000000..4e7be7ddd3d7
--- /dev/null
+++ b/dev-python/stevedore/stevedore-1.30.1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6,7} )
+
+inherit distutils-r1
+
+DESCRIPTION="Manage dynamic plugins for Python applications"
+HOMEPAGE="https://github.com/openstack/stevedore https://pypi.org/project/stevedore/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc test"
+
+CDEPEND=">=dev-python/pbr-2.0.0[${PYTHON_USEDEP}]
+	!~dev-python/pbr-2.1.0[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	${CDEPEND}
+	test? (
+		>=dev-python/mock-2.0.0[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		>=dev-python/coverage-4.0[${PYTHON_USEDEP}]
+		!~dev-python/coverage-4.4[${PYTHON_USEDEP}]
+		>=dev-python/stestr-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/reno-1.8.0[${PYTHON_USEDEP}]
+		!~dev-python/reno-2.3.1[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/pillow-2.4.0[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.6.5[${PYTHON_USEDEP}]
+		!~dev-python/sphinx-1.6.6[${PYTHON_USEDEP}]
+		!~dev-python/sphinx-1.6.7[${PYTHON_USEDEP}]
+		>=dev-python/openstackdocstheme-1.18.1[${PYTHON_USEDEP}]
+		>=dev-python/reno-1.8.0[${PYTHON_USEDEP}]
+		!~dev-python/reno-2.3.1[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="
+	${CDEPEND}
+	>=dev-python/six-1.10.0[${PYTHON_USEDEP}]"
+
+python_prepare_all() {
+	# Delete spurious data in requirements.txt
+	sed -e '/^pbr/d' -i requirements.txt || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && esetup.py build_sphinx
+}
+
+python_test() {
+	nosetests --verbosity=3 stevedore || die
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/build/html/. )
+
+	distutils-r1_python_install_all
+}