dev-qt/qtprintsupport: Fix revdeps segfault if built with USE=-cups

Tested-by: David Flogeras <dflogeras2@gmail.com>
Thanks-to: David Flogeras <dflogeras2@gmail.com>
Closes: https://bugs.gentoo.org/704936
Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 44 insertions, 0 deletions

diff --git a/dev-qt/qtprintsupport/qtprintsupport-5.13.2-r1.ebuild b/dev-qt/qtprintsupport/qtprintsupport-5.13.2-r1.ebuild
new file mode 100644
index 000000000000..7ce0cf6ddbd5
--- /dev/null
+++ b/dev-qt/qtprintsupport/qtprintsupport-5.13.2-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+QT5_MODULE="qtbase"
+VIRTUALX_REQUIRED="test"
+inherit qt5-build
+
+DESCRIPTION="Printing support library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
+fi
+
+IUSE="cups gles2"
+
+RDEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtgui-${PV}[gles2=]
+	~dev-qt/qtwidgets-${PV}[gles2=]
+	cups? ( >=net-print/cups-1.4 )
+"
+DEPEND="${RDEPEND}
+	test? ( ~dev-qt/qtnetwork-${PV} )
+"
+
+QT5_TARGET_SUBDIRS=(
+	src/printsupport
+	src/plugins/printsupport
+)
+
+QT5_GENTOO_CONFIG=(
+	cups
+)
+
+PATCHES=( "${FILESDIR}/${P}-no-cups.patch" ) # bug #704936, QTBUG-80945
+
+src_configure() {
+	local myconf=(
+		$(qt_use cups)
+		-opengl $(usex gles2 es2 desktop)
+	)
+	qt5-build_src_configure
+}