dev-ruby/hiera-eyaml: add 3.0.0

Fixes: https://bugs.gentoo.org/680050
Signed-off-by: Hans de Graaff <graaff@gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

1 files changed, 47 insertions, 0 deletions

diff --git a/dev-ruby/hiera-eyaml/hiera-eyaml-3.0.0.ebuild b/dev-ruby/hiera-eyaml/hiera-eyaml-3.0.0.ebuild
new file mode 100644
index 000000000000..22b09b8ad766
--- /dev/null
+++ b/dev-ruby/hiera-eyaml/hiera-eyaml-3.0.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+USE_RUBY="ruby23 ruby24 ruby25"
+
+RUBY_FAKEGEM_TASK_DOC=""
+RUBY_FAKEGEM_EXTRADOC="README.md CHANGELOG.md PLUGINS.md"
+
+RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Encrypted YAML backend for hiera"
+HOMEPAGE="https://github.com/TomPoulton/hiera-eyaml"
+SRC_URI="https://github.com/TomPoulton/hiera-eyaml/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="3"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+ruby_add_rdepend ">=dev-ruby/highline-1.6.19:*"
+ruby_add_rdepend "dev-ruby/optimist"
+
+ruby_add_bdepend "test? ( dev-util/cucumber ~dev-util/aruba-0.6.2 <app-admin/puppet-6 dev-ruby/hiera-eyaml-plaintext )"
+
+all_ruby_prepare() {
+	# Fix highline dependency to be compatible with more versions.
+	sed -i -e '/highline/ s/~>/>=/' \
+		-e '/gem.files/d' ${RUBY_FAKEGEM_GEMSPEC} || die
+
+	sed -i -e 's:/tmp:'${T}':' \
+		features/sandbox/puppet/environments/local/modules/test/manifests/run.pp \
+		features/sandbox/puppet-hiera-merge/environments/local/modules/test/manifests/run.pp \
+		features/puppet.feature
+}
+
+each_ruby_prepare() {
+	# Run tests with the correct ruby interpreter
+	sed -i -e 's:I run `eyaml:I run `'${RUBY}' '${S}'/bin/eyaml:' features/*.feature || die
+
+}
+
+each_ruby_test() {
+	${RUBY} -S cucumber --format progress features || die
+}